Accept POST parameters with FCGI

Question

I am trying to get URL parameters using CGI and FCGI.

When executing the script on my browser I am only getting parameters of my first request, but the request $count does increment.

use CGI;
use FCGI;

my $fcgiRequest = FCGI::Request();
while ($fcgiRequest->Accept() >= 0)
{
    print("Content-type: text/html\r\n\r\n", ++$count); 
    my $q = new CGI;  
    print "name = " . $q->param("name") ; 
    print "\n";
}

Answer 1

You can't use CGI.pm and FCGI.pm together like this. You need some glue-code in between, because CGI needs to read stuff from the environment, and it can't in the way you invoke it.

There is a module CGI::Fast included with Perl that does this for you. Instead of using CGI and FCGI, you just use CGI::Fast and change a bit of code.

use strict;
use warnings;
use CGI::Fast;

my $count;
while (my $q = CGI::Fast->new) {
    # $q is a fresh CGI object for the current request

    print("Content-type: text/html\r\n\r\n", ++$count);
    print "name = " . $q->param("name") ; 
    print "\n";
}

If you already have a CGI script, you could put that in a function and call it inside of that loop.

If you're interested in how CGI::Fast works, feel free to take a look at its source code on CPAN. The main thing is that the environment and the file handles (for STDOUT and STDERR) need to be mapped to each new request, while your implementation has CGI always parse the first one.

Please note that the examples in both the perldoc and on CPAN that I have linked are very out-of-date and don't represent modern Perl code.

---

Today, you would probably not use CGI any more, as it has been removed from current Perl releases. Instead, you could take a look at the PSGI interface specification and Plack on how to implement it. The good thing about that is that it provides a clear interface across different deployment-technologies (such as CGI and Fast CGI). You can just let your program run as a simple CGI with Apache or nginx, or as a persistent FCGI process with Apache or other webservers, or as a standalone application through various Plack webservers that are written in Perl and are tailored for specific purposes.

Answer 2

Once a CGI.pm object is created for a request, it's reused there on out.

You can reset CGI.pm by adding the following to the end of the loop:

CGI::_reset_globals();