Accessing the grouped nodes with xpath to build a constant output

Question

I have the below xml

<toPay>
<Pay>
    <amount>1111</amount>       
    <accountNumber>223128987</accountNumber>
    <payType>PAYROLL</payType>
</Pay>
<Pay>
    <amount>2222</amount>
    <accountNumber>123128987</accountNumber>
    <payType>PAYROLL</payType>
</Pay>
<Pay>
    <amount>333</amount>
    <accountNumber>645032</accountNumber>
    <payType>MAIN</payType>
</Pay>

I need the output in this format:

<root>
<element>
    <amount>1111</amount>
    <accountNumber>223128987</accountNumber>
</element>
<element>
    <amount>2222</amount>
    <accountNumber>223128987</accountNumber>
</element>
<element>
    <amount></amount>
    <accountNumber></accountNumber>
</element>
<element>
    <amount></amount>
    <accountNumber></accountNumber>
</element>

I have written the following code:

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:key name="groups" match="payType" use="." />

<xsl:template match="/toPay/Pay">
    <root>
        <xsl:apply-templates select="payType[generate-id() = generate-id(key('groups', .)[1])]" />
    </root>
</xsl:template>

<xsl:template match="payType">
    <xsl:variable name="currentGroup" select="." />
        <xsl:if test="$currentGroup = 'PAYROLL'">

            <xsl:for-each select="key('groups', $currentGroup)">
                <element>
                    <xsl:if test="position() = 1">
                        <amount>
                            <xsl:value-of select="../amount" />
                        </amount>
                        <accountNumber>
                            <xsl:value-of select="../accountNumber" />
                        </accountNumber>
                    </xsl:if>                   
                    <xsl:if test="position() = 2">
                        <amount>
                            <xsl:value-of select="../amount" />
                        </amount>
                        <accountNumber>
                            <xsl:value-of select="../accountNumber" />
                        </accountNumber>
                    </xsl:if>
                </element>
            </xsl:for-each>
        </xsl:if>
</xsl:template>

But the issue I am facing is that - I cannot access the grouped nodes for paytype -PAYROLL. The only way I know is with position but my requirement to enter always 4 element nodes always in the output whether or not the nodes in the source xml with PAYtype -PAYROLL exists or not. If exists then values of the same eeds to be populated if not then xml tags with no values.

Any help is much appreciated - either xslt 1.0 or 2.0.

Answer 1

If I understood your explanation correctly, you could do something very simple - even if a bit primitive:

<xsl:template match="/toPay">
    <xsl:variable name="payroll" select="Pay[payType='PAYROLL']" />
    <root>
        <element>
            <amount>
                <xsl:value-of select="$payroll[1]/amount" />
            </amount>
            <accountNumber>
                <xsl:value-of select="$payroll[1]/accountNumber" />         
            </accountNumber>
        </element>
        <element>
            <amount>
                <xsl:value-of select="$payroll[2]/amount" />
            </amount>
            <accountNumber>
                <xsl:value-of select="$payroll[2]/accountNumber" />         
            </accountNumber>
        </element>
        <element>
            <amount>
                <xsl:value-of select="$payroll[3]/amount" />
            </amount>
            <accountNumber>
                <xsl:value-of select="$payroll[3]/accountNumber" />         
            </accountNumber>
        </element>
        <element>
            <amount>
                <xsl:value-of select="$payroll[4]/amount" />
            </amount>
            <accountNumber>
                <xsl:value-of select="$payroll[4]/accountNumber" />         
            </accountNumber>
        </element>
    </root>
</xsl:template>

I see no requirement for grouping of anything.

---

Here's a slightly more elegant version:

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/toPay">
    <xsl:variable name="payroll" select="Pay[payType='PAYROLL']" />
    <root>
        <xsl:apply-templates select="$payroll"/>
        <xsl:for-each select="1 to 4 - count($payroll)">
             <element>
                <amount/>
                <accountNumber/>
              </element>
        </xsl:for-each>
    </root>
</xsl:template>

<xsl:template match="Pay">
    <element>
        <xsl:copy-of select="amount, accountNumber"/>
    </element>
</xsl:template>

</xsl:stylesheet>

Demo: http://xsltransform.net/6pS1zDr

Answer 2

I also see no need for grouping, if you want to output empty elements for those elements that are not present then with XSLT 2.0 you can use

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">

    <xsl:output indent="yes"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="toPay">
        <root>
            <xsl:variable name="payroll" select="Pay[payType = 'PAYROLL']"/>
            <xsl:apply-templates select="$payroll"/>
            <xsl:for-each select="(count($payroll) + 1) to 4">
              <element>
                <amount></amount>
                <accountNumber></accountNumber>
            </element>  
            </xsl:for-each>
        </root>
    </xsl:template>

    <xsl:template match="Pay">
        <element>
            <xsl:apply-templates select="* except payType"/>
        </element>
    </xsl:template>
</xsl:transform>