AS3. MovieClip over other movieclip instead of mouse_over.

Question

I have action

MC1.addEventListener (MouseEvent.MOUSE_OVER, MC1_over);

can a use other MC instead of Mouse? In other words, when MC2 will be over MC1, my action will start. How do that? Thanks for help

Answer 1

You'll have to check for intersection. It's called HitTesting and there are several ways to approach this. But first - it won't be an Event anymore, you'll have to check for an intersection in every frame. So first of all, we need to create a new Event.ENTER_FRAME listener.

addEventListener(Event.ENTER_FRAME, onEnterFrame);

function onEnterFrame(e:Event):void
{
    //Your code will go here
}

Second, we check our objects for an intersection of their boudary rectangles. It's ok if you have sqare or rectangular movieclips, if your MCs are more complex (two circles for example) you'll have to use other ways of getting this intersection.

    addEventListener(Event.ENTER_FRAME, onEnterFrame);

function onEnterFrame(e:Event):void
{
    if(MC1.getRect(this).intersects(MC2.getRect(this)))
    {
        //Two movieclips are intersecting
    }
}

Third, as long as this condition will be true as long as your MCs are intersecting, we need to define a flag that will tell us if we've already done something we wanted to do.

var alreadyHandled:Boolean = false;

addEventListener(Event.ENTER_FRAME, onEnterFrame);

function onEnterFrame(e:Event):void
{
    if(MC1.getRect(this).intersects(MC2.getRect(this)))
    {
        if(!alreadyHandled)
        {
            doSomething();
            alreadyHandled = true;
        }
    }
    else
    {
        //When our movieclips are apart again, we reset our helping variable
        alreadyHandled = false;
    }
}

function doSomething():void
{
    //We do what we want to do if our MCs are intersecting
}

If you want to do something continiously, when your movieclips are intersecting, just ignore that helping flag thing.

And by the way, I suggest you to start names your variables with a lowercase letter. In AS3 only Classes and Interfaces have names that start with a capital letter.

Answer 2

Thank you. Everything works great when I do this on new as3 file. But i need to use this in class document When i use

addEventListener(Event.ENTER_FRAME, onEnterFrame);

function onEnterFrame(e:Event):void
{
    if(MC1.getRect(this).intersects(MC2.getRect(this)))
    {
        trace("intersects")
    }
}

Erron#1034: cannot convert type global@23b3a0d1 on flash.display.DisplayObject.

Perhaps You known where is problem?