AT / CMQTT, subscription silently removed after publish (cmqttpub)

Question

I am using MQTT on a SIM7500 LTE modem. I can connect to some mqtt broker after sending a bunch of AT and MQTT commands.

The thing I didn't expect to happen, is when I publish a topic from my modem, I loose the subscription I had open. Regardless of the topic name I subscribed to. After a publish from my modem, my modem no longer receives bytes when I publish on any subscribed topic on the broker.

I checked the documentation on the modem again, I can't find any reference to this behavior.

Anybody with knowledge on AT/CMQTT can explain if this is "expected behavior"? I can't imagine it's a bug in the modem. So either I am using things in the wrong way, or there is a reason for this.

A screenshot which shows the commands being sent/received:

In text:

startup commands left out for convenience (atz, ate0, at+cgatt=1, at+cgact=1,1)

MCU ==> Modem                                 MCU <== Modem

AT+CMQTTCONNECT=0,"someipaddress:port,90,1    
                                              +CMQTTCONNECT: 0,0
AT+CMQTTSUBTOPIC=0,5,2
                                              >
stm32
                                              OK
AT+CMQTTSUB=0
                                              OK

from this moment on, I have a live subscription, I published 2 messages on that topic which are received and passed through to my MCU

MCU ==> Modem                                 MCU <== Modem

                                              hello
                                              hello

AT+CMQTTTOPIC=0,17
                                              >
t/867584034403399
                                              OK
AT+CMQTTPAYLOAD=0,5
                                              >
hello
                                              OK

from this point onwards, the subscription is lost. Whatever I publish on 'stm32', it no longer is received on my uart connected to my modem.

Answer 1

A simple answer to your question could be that you may have failed to connect to the GPRS network.

Try reinitializing the modem with AT commands and see if actually solves the problem.

I can not see your code, but I can share with you a simple implementation made using the arduino library TinyGSM which is wildely used when interacting with such type of modems.

This code is compiled and flashed on an ESP32 - DevKit V1 using the PlatformIO plugin.

Make Sure to substitute the GPRS_APN, GPRS_USER and GPRS_PASSWORD with your current settings.

#define TINY_GSM_MODEM_SIM7600 // must be defined before all inclusions
#include <Arduino.h>
#include <HardwareSerial.h>
#include <TinyGsmClient.h>
HardwareSerial mySerial(2);
#define SerialAT mySerial

// I Will subscribe and publish on the same topic
String topic = "Alby/sim7600/test/data";
String message = "Hello World!";

// Initializing the modem
TinyGsm modem(SerialAT);
TinyGsmClient client(modem);


void initModem(const char *apn, const char *user, const char *password) {

   Serial.println("System start.");
   modem.init();      // initializes the modem for the first time
   Serial.println("Modem: " + modem.getModemName());
   Serial.println("Modem: " + modem.getModemInfo());
   Serial.println("Searching for provider.");
   if(!modem.waitForNetwork(15000))
   {
       Serial.println("fail");
       modem.restart();
   }
   Serial.println("Connected to TM.");
   Serial.println("Signal Quality: " + String(modem.getSignalQuality()));
 
   Serial.println("Connecting to GPRS network.");
   if (!modem.gprsConnect(apn, user, password))
   {
       Serial.println("fail");
       modem.restart();
   }

   if(modem.isGprsConnected()){
       Serial.println("Gprs connected");
   }
}

bool sendCommand(String command){
    Serial.println(">> " + command);
    SerialAT.println(command); //connecting to hivemq MQTT broker
    delay(500);
    String rxString = "";
    while(SerialAT.available()) {
       rxString += SerialAT.readString();
    }
    Serial.print("<< ");
    Serial.println(rxString);
    int rx = rxString.indexOf("ERROR");
    if (rx != -1) {
        return false;
    }
    return true;
}

void setup() {

    Serial.begin(115200);
    SerialAT.begin(115200);

    // Initializing the Modem
    initModem(GPRS_APN, GPRS_USER, GPRS_PASSWORD);
    // Starting MQTT 
    if(!sendCommand("AT+CMQTTSTART")){
       Serial.println("Problems...");
       while(1);
    }
    // Acquiring client (unique name) with index 0
    if(!sendCommand("AT+CMQTTACCQ=0,\"Alby0102Sim7600L\"")){
        Serial.println("Problems...");
        while(1);
    }
 // connecting to public broker
if(!sendCommand("AT+CMQTTCONNECT=0,\"tcp://broker.hivemq.com:1883\",90,1")) 
{
    Serial.println("Problems...");
    while(1);
}
// subscribing to topic
if(!sendCommand("AT+CMQTTSUBTOPIC=0,"+String(topic.length())+",1")){
    Serial.println("Problems...");
    while(1);
}
if(!sendCommand(topic)){
    Serial.println("Problems...");
    while(1);
}
// send subscription --> will fail if not connected to the network
if(!sendCommand("AT+CMQTTSUB=0")){
    Serial.println("Problems...");
    while(1);
}
// setting topic
if(!sendCommand("AT+CMQTTTOPIC=0," + String(topic.length()))){
    Serial.println("Problems...");
    while(1);
}

if(!sendCommand(topic)){
    Serial.println("Problems...");
    while(1);
}
// setting payload
if(!sendCommand("AT+CMQTTPAYLOAD=0,"+String(message.length()))){
    Serial.println("Problems...");
    while(1);
}

if(!sendCommand(message)){
    Serial.println("Problems...");
    while(1);
}
// publishing command
if(!sendCommand("AT+CMQTTPUB=0,1,60")){
    Serial.println("Problems...");
    while(1);
}

long start = millis();
while(millis()-start <= 10000){
    String s = SerialAT.readString();
    if(s){
        Serial.println("Reading: > " + s);
    }
}
// Make sure to disconnect from server, or may cause problems at reboot time
if(!sendCommand("AT+CMQTTDISC=0,60")){
    Serial.println("Problems...");
    while(1);
}
// releasing client index 0
if(!sendCommand("AT+CMQTTREL=0")){
    Serial.println("Problems...");
    while(1);
}
// stop MQTT
if(!sendCommand("AT+CMQTTSTOP")){
    Serial.println("Problems...");
    while(1);
}

}

void loop() {}