C-SPARQL query - match exact string literal

Question

I am working with C-SPARQL and I want to query triples received from a stream. However I encountered an issue when using a query in which I want to match an exact string literal. I usually get a result with my queries (data is coming from the string) but when I add a exact match for a string value for a literal, I always don't get any results. As if there is no match found. However if I look at all triples received from my stream there are entries that would match my string literal.

Here is an example of my query:

REGISTER QUERY LogStream AS
PREFIX person: <http://vocab/Person#> 
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
SELECT ?s 
FROM STREAM <ws://localhost:8124/tw/stream> [RANGE 5s STEP 1s] 
WHERE { 
?s person:name "Huber" .
}

I also tried working with filters and regex which are the following 2 examples:

REGISTER QUERY LogStream AS
PREFIX person: <http://vocab/Person#> 
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
SELECT ?s ?o 
FROM STREAM <ws://localhost:8124/tw/stream> [RANGE 5s STEP 1s] 
WHERE { 
 ?s person:name ?o FILTER ( ?o = "Huber" ) .
}

REGISTER QUERY LogStream AS
PREFIX person: <http://vocab/Person#> 
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
SELECT ?s ?o 
FROM STREAM <ws://localhost:8124/tw/stream> [RANGE 5s STEP 1s] 
WHERE { 
 ?s person:name ?o FILTER (regex(?o, '^Huber$')) .
}

None of the queries give my any results as if there are no matches.

If I just execute the following query, I get a lot of results with name = Huber:

REGISTER QUERY LogStream AS
PREFIX person: <http://vocab/Person#> 
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
SELECT ?s ?o 
FROM STREAM <ws://localhost:8124/tw/stream> [RANGE 5s STEP 1s] 
WHERE { 
 ?s person:name ?o .
}

---

I am not sure if C-SPARQL supports all features of SPARQL. I read in a different post that round() is not supported in C-SPARQL. Since the match of an exact String is a basic feature, at least in my opinion, I am not sure if I might do something wrong or if I miss some details. I tried the queries in SPARQL, querying a triplestore, and there all queries work just fine.

So, I am a bit confused why the string match is not working here in C-SPARQL. Does anyone has some hints or suggestions?

---

EDIT (further information about how my data looks like):

The data I am trying to query using C-SPARQL are JSON-LD entries coming from a Web stream. The stream is created and published via Triplewave.

Here would be a small example of a JSON-LD:

[
  {
    "@id": "http://Stream/d7e4e816-0931-42ce-a21a-cbfaa552855d",
    "http://www.w3.org/ns/prov#generatedAtTime": [
      {
        "@value": "2018-11-14T07:08:45.182Z"
      }
    ],
    "@graph": [
      {
        "@id": "http://schema.org/Person#1234",
        "http://schema.org/name": [
          {
            "@value": "Huber"
          }
        ]
      },
      {
        "@id": "http://schema.org/Job#1234",
        "http://schema.org/title"": [
          {
            "@value": "Professor"
          }
        ]
      }
    ]
  }
]

There is no type information or any language tag.

In order to query my web stream using C-SPARQL I implemented a RdfStream which receives the JSON-LD data via a websocket and created RdfQuadruple of all entries in my graph and puts it into the RdfStream.

An example of a RdfQuadruple is this:

http://schema.org/Person#1234 http://schema.org/name Huber . 

Answer 1

The STR( value ) function solved my issue. I have to convert the value to a string beforehand

So the following query worked:

REGISTER QUERY LogStream AS
PREFIX person: <http://vocab/Person#> 
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
SELECT ?s ?o 
FROM STREAM <ws://localhost:8124/tw/stream> [RANGE 5s STEP 1s] 
WHERE { 
 ?s person:name ?o FILTER ( str(?o) = "Huber" ) .
}

Thank you for your suggestions.