Can I write a screen magnifier in RealBasic?

Question

I want to create a screen magnifier in RealBasic but don't see any classes or APIs for reading areas of the screen that I can then render to my window.

Anything?

Side-question: If I can't read entire areas, can I at least do per-pixel reading to simulate an eye-dropper tool that reads the pixel's color under the cursor?

Answer 1

There are several ways that both a magnifier and a eye-dropper can be made with Realbasic (shameless plug: I wrote an eyedropper in RealBasic a while ago.) It's very simple, just call the System.Pixel function using System.MouseX and System.MouseY as its parameters. System.Pixel returns a Color corresponding to the color of the pixel at the screen coordinates you specify.

With this color information you can (obviously) show the color at a larger scale by drawing to a Picture object or a Canvas control (as with an eyedropper.)

This method can be used for something like a magnifier, but probably shouldn't be. Drawing pixel-by-pixel in RealBasic can be quite slow, which with realtime tasks like a magnifier will lead to performance issues and flickering.

Under Windows, and likely under Mac OS X and GTK+, there are API functions which allow you to capture an area of the screen, which is useful for screenshots, and for manipulating bitmap images using a number of standard algorithms.

Here is a simple function which calls the Windows API to capture an 800x600 portion of the screen, magnify it by 3, and copy it into a Picture object:

 Function GetZoomedPic() As Picture
  Declare Function GetDesktopWindow Lib "User32" () As Integer
  Declare Function GetDC Lib "User32" (HWND As Integer) As Integer
  Declare Function StretchBlt Lib "GDI32" (destDC As Integer, destX As Integer, destY As Integer, destWidth As Integer, destHeight As Integer, _
  sourceDC As Integer, sourceX As Integer, sourceY As Integer, sourceWidth As Integer, sourceHeight As Integer, rasterOp As Integer) As Boolean
  Declare Function ReleaseDC Lib "User32" (HWND As Integer, DC As Integer) As Integer

  Const CAPTUREBLT = &h40000000
  Const SRCCOPY = &HCC0020
  Dim coordx, coordy As Integer
  Dim magnifyLvl As Integer = 3
  Dim screenCap As New Picture(800, 600, 32)
  coordx = System.MouseX - (screenCap.Width \ (magnifyLvl * 2))
  coordy = System.Mousey - (screenCap.Height \ (magnifyLvl * 2))
  Dim rectWidth, rectHeight As Integer
  rectWidth = screenCap.Width \ magnifyLvl
  rectHeight = screenCap.Height \ magnifyLvl

  Dim deskHWND As Integer = GetDesktopWindow()
  Dim deskHDC As Integer = GetDC(deskHWND)
  Call StretchBlt(screenCap.Graphics.Handle(1), 0, 0, screenCap.Width, screenCap.Height, DeskHDC, coordx, coordy, rectWidth, _
  rectHeight, SRCCOPY Or CAPTUREBLT)
  Call ReleaseDC(DeskHWND, deskHDC)

  Return screenCap
End Function

Around the same time I wrote that Eyedropper, I also wrote a basic magnifier project. You can download the project file here. In addition to demonstrating the above function, it can also serve as a basic demonstration of drawing to a Canvas without flickering, of using a RealBasic Picture object with Windows GDI Device Contexts and the use of threads to offload work from the main thread.

Answer 2

Take a look at this thread on the Real Software forums on this very topic. Looks like there are a number of solutions you can try.

http://forums.realsoftware.com/viewtopic.php?f=10&t=7818&hilit=screen+magnifier