Can't configure "database shared throughput" on cosmosdb with Terraform

Question

My context

Trying to deploy azure cosmosdb (MongoDB) with Terraform.

I need to configure database shared throughput.

My issues

I can't figure out how to do this, I don't even know if it is supported.

I tried this:

resource "azurerm_cosmosdb_account" "cosmosdb" {
  name                                  = "mycosmosdb1
  resource_group_name                   = "rg1"
  location                              = "westeurope"
  offer_type                            = "Standard"
  kind                                  = "MongoDB"      
  mongo_server_version                  = "4.2"

   capacity {
     total_throughput_limit = 1000
   }

  capabilities {
    name = "EnableMongo"
  }
  capabilities {
    name = "DisableRateLimitingResponses"
  }
}

resource "azurerm_cosmosdb_mongo_database" "cosmosdb_mongo_database" {
  name = "db1"

  resource_group_name = azurerm_cosmosdb_account.cosmosdb.resource_group_name
  account_name        = azurerm_cosmosdb_account.cosmosdb.name
}

resource "azurerm_cosmosdb_mongo_collection" "cosmosdb_mongo_collection" {
  database_name       = "db1"
  name                = "col1"
  resource_group_name = azurerm_cosmosdb_account.cosmosdb.resource_group_name
  account_name        = azurerm_cosmosdb_account.cosmosdb.name

  index {
    keys   = ["_id"]
    unique = false
  }
}

But no impact.

What I need

• Is it currently supported by azurerm ?
• How I can do this?

Thank you

Answer 1

I tried to configure "database shared throughput" on cosmosdb with Terraform and I was able to provision the requirement successfully.

In the configuration you provided you have set up the throughput in the wrong resource. To configure shared throughput for a database, you should not use azurerm_cosmosdb_account, but a different resource.

To configure shared throughput for a CosmosDB MongoDB database, you should set the throughput attribute in the azurerm_cosmosdb_mongo_database resource. The throughput setting is not part of the azurerm_cosmosdb_account resource.

My terraform configuration:

provider "azurerm" {
    features {}
}

resource "azurerm_resource_group" "example" {
  name     = "demorg-vk"
  location = "West Europe"
}

resource "azurerm_cosmosdb_account" "cosmosdb" {
  name                = "vkcosmosdb1"
  location            = azurerm_resource_group.example.location
  resource_group_name = azurerm_resource_group.example.name
  offer_type          = "Standard"
  kind                = "MongoDB"
  mongo_server_version = "4.2"

  consistency_policy {
    consistency_level       = "Session"
  }

  geo_location {
    location          = azurerm_resource_group.example.location
    failover_priority = 0
  }

  capabilities {
    name = "EnableMongo"
  }

  capabilities {
    name = "DisableRateLimitingResponses"
  }
}

resource "azurerm_cosmosdb_mongo_database" "cosmosdb_mongo_database" {
  name                = "vkdb1"
  resource_group_name = azurerm_cosmosdb_account.cosmosdb.resource_group_name
  account_name        = azurerm_cosmosdb_account.cosmosdb.name
  throughput          = 1000
}

resource "azurerm_cosmosdb_mongo_collection" "cosmosdb_mongo_collection" {
  name                = "vkcol1"
  database_name       = azurerm_cosmosdb_mongo_database.cosmosdb_mongo_database.name
  resource_group_name = azurerm_cosmosdb_account.cosmosdb.resource_group_name
  account_name        = azurerm_cosmosdb_account.cosmosdb.name

  index {
    keys   = ["_id"]
    unique = false
  }
}

Output: