Convert JSON Objects to JSON object array Without programming Language (exception shell scripting)

Question

I have file containing Multiple JSON Objects and need to covert them to JSON. I have bash and Excel installed, but cannot install any other tool.

{"name": "a","age":"17"}
{"name":"b","age":"18"}

To:

[{"name": "a","age":"17"},
{"name":"b","age":"18"}]

Answer 1

Assuming one object per line as shown by OP question

echo -n "["; while read line; do echo "${line},"; done < <(cat test.txt) | sed -re '$ s/(.*),/\1]/'

Result:

[{"name": "a","age":"17"},
{"name":"b","age":"18"}]

Answer 2

Inspired by https://askubuntu.com/a/475804

awk '(NR==FNR){count++} (NR!=FNR){ if (FNR==1) printf("["); printf("%s", $0); print (FNR==count)?"]":"," } END {if (count==0) print "[]"}' file file

A less compact but more readable version:

awk '
  (NR==FNR) {
    count++;
  }
  (NR!=FNR) {
    if (FNR==1)
      printf("[");
    printf("%s", $0);
    if (FNR==count)
      print "]";
    else
      print ",";
  }
  END {
    if (count==0) print "[]";
  }' file file

The trick is to give the same file twice to awk. Because NR==FNR is always true for the first file, there is a first parse dedicated to counting the number of lines into variable count.

The second parse with NR!=FNR will apply the following algorithm for each line:

• Write [ for the first line only
• Then write the record, using printf instead of print in order to avoid the newline ending
• Then write either ] or , depending on whether we are on the last line or not, using print in order to end with a newline

The END command is just a failsafe to output an empty array in case the file is empty.

Answer 3

Assumptions:

• no requirement to (re)format the input data

Sample input:

$ cat raw.dat
{"name": "a","age":"17"}
{"name":"b","age":"18"}
{"name":"C","age":"23"}

One awk idea:

awk 'BEGIN {pfx="["} {printf "%s%s",pfx,$0; pfx=",\n"} END {printf "]\n"}' raw.dat

Where:

• for each input line we printf the line without a terminating linefeed
• for the first line we use a prefix (pfx) of [
• for subsequent lines the prefix (pfx) is set to ,\n (ie, terminate the previous line with ,\n)
• once the file has been processed we terminate the last input line with a printf "]\n"
• requires a single pass through the input file

This generates:

[{"name": "a","age":"17"},
{"name":"b","age":"18"},
{"name":"C","age":"23"}]

---

Making sure @chepner's comment (re: a sed solution) isn't lost in the mix:

sed '1s/^/[/;2,$s/^/,/;$s/$/]/' raw.dat

This generates:

[{"name": "a","age":"17"}
,{"name":"b","age":"18"}
,{"name":"C","age":"23"}]

NOTE: I can remove this if @chepner wants to post this as an answer.