Error, "[" unexpected In Maple

Question

I have the following code and the annoying Error, "[" unexpected In Maple error keeps coming up. Does anyone see what it is that I am doing wrong because I have been staring at the screen for hours and still dont see it.

Relations:=proc(n::posint,fb::Array,{mindeps::posint:=5,verbose::truefalse:=false})
local s,np,f,j,g,f1,f2,i;
s:=isqrt(n);
np:=ArrayNumElems(fb);
f:=[];
j:=1;

g:=np+mindeps;
while nops(f) < g do
  f1:=FBTrialDivision(n,s-j+1,fb);
  f2:=FBTrialDivision(n,s+j,fb);
  f:=[op(f),f1,f2];
  j:=j+1
end do;
if verbose then
  printf("smooth",g,2*j-2)
else
  print("");
  print(2*j-2)

end if
[Vector([seq(f[i][1], i = 1..nops(f))]),Vector([seq(f[i][2], i = 1..nops(f))]),
LinearAlgebra:-Transpose(Matrix([seq(f[i][3], i = 1..nops(f))]))]

end proc:

Second one:

FindFactors:=proc(n,rels,deps)
local fact, i, x, y;
fact:=1;
for i to nops(deps) while fact = 1 or fact = n do
  x:=mul(j,j=rels[1]~deps[i]);
  y:=isqrt(mul(j,j=rels[2]~deps[i]));
  fact:=igcd(x+y,n)
end do;
if fact <> 1 and fact <> n then
  ``(fact)*``(iquo(n,fact))
else
  print("no trivial")
end if;
end proc:

Answer 1

There is no terminator for the preceding line.

As plaintext 1D Maple Notation code, the previous line,

end if

is missing a statement terminator (either colon or semicolon). That's the cause of the error.

I notice that in several; places your code makes use of the fact that terminators are not required on lines that precede an end if, end do, end proc, etc. You may be seeing one of the dangers of that habit: when you edit and add a new statement between such a line and the end that trails it, you have to remember to add a statement terminator to the line which is no longer "last". Some people find that it just pays off to keep things simple and always use statement terminators, whether the current line needs it or not.