Errorlevel with choice in batch files executes wrong cases

Question

can someone tell me how can I make errorlevel stop taking value 1 or bigger? I want it to take into consideration only the exact value. If I choose 2, I want it to take the second option. Right now if I choose '1', it executes the option for DLL file instead of LOG. I tried different versions like: if errorlevel 1, tried using brackets with else etc. but none of them worked. Whats wrong with this code?

@echo off
cls
choice /C 12 /M "dll or log?"

if %errorlevel%=="2" dir %1\*.dll >> %2.txt
echo DLL
goto end
if %errorlevel%=="1" dir %1\*.log >> %3.txt
echo LOG
goto end
:end
exit /b

Answer 1

this resolve:

@echo off
cls
rem choice /C 12 /M "dll or log?"
choice /C 12 /M "log or dll?"

if %errorlevel%==2 (dir %1\*.dll >> %2.txt
echo DLL
goto end)
if %errorlevel%==1 (dir %1\*.log >> %3.txt
echo LOG
goto end)
:end
exit /b

you need control the flow whith "(" ")" and the " around the errorlevel number is not necessary.

---

BONUS

This an alternative method that is more flexible:

@echo off

if "%~3"=="" echo lack of parameters & goto :EOF

cls
choice /C 12 /M "log or dll?"
Goto Choice%ErrorLevel%

:Choice2
  dir "%~1\*.dll" >> "%~2.txt"
  echo DLL in %~1
goto end

:Choice1
  dir "%~1\*.log" >> "%~3.txt"
  echo LOG in %~1
goto end

:end
exit /b

The ~ in the parameters remove eventual sorround double quote. Then the surrond quoted added can prevent parameters with space inside.

Answer 2

The ERRORLEVEL value is always numberic. The "compare ops" can be used. See IF /? for more infornation.

Quoting file system paths is needed in case there are SPACE or other special characters in the path. As mentioned by @Gerhard, using a TILDE in "%~3" removes any existing QUOTATION MARK characters around the %3 parameter.

BTW, this script does not check that %1, %2%, or %3 have any actual value or that the value it has is usable.

@echo off
cls
SETLOCAL ENABLEEXTENSIONS
choice /C 12 /M "dll or log?"

if %errorlevel% EQU 2 (
    dir "%~1\*.dll" >> "%~2.txt"
    echo DLL
    goto end
)
if %errorlevel% EQU  1 (
    dir "%~1\*.log" >> "%~3.txt"
    echo LOG
    goto end
)

:end
exit /b