FINDSTR and RegEx issuse

Question

I have a batch file that asks for input, stores this input in a var and then uses the var in a ping. I need to make sure that the input matches one of several naming conventions

Naming conventions:
PCX1 can be as high as 100
GENPRT1 can be as high as 100
NETPRT1 can be as high as 100
FAXPRT1 can be as high as 100

So if i enter 12 it will not work but if I enter PCX12 it will.

Everything in the script works except the regex. How can i get this to work?

if "%sta%" == "findstr %sta% ^PCX[0-9]*[0-9]*[0-9]$ \i" (
    echo The syntax is correct
    goto PING
) else (
    set errmsg=The syntax is wrong
    goto START
)

Answer 1

This should help:

^(PCX|GENPRT|NETPRT|FAXPRT)([\d]|0[\d]|00[\d]|0[\d][\d]|[\d][\d]|100)$

Answer 2

@echo off
    setlocal disabledelayedexpansion

:start
    set /p "sta=What ? "

    cmd /v /d /q /c "(echo(!sta!)" ^
     | findstr /i /r /b /e "PCX[0-9]* GENPRT[0-9]* NETPRT[0-9]* FAXPRT[0-9]*" ^
     | findstr /r /e "[^0-9][1-9] [^0-9][1-9][0-9] [^0-9]100" > nul 

    if errorlevel 1 (
        echo The syntax is wrong
        goto :start
    )

    echo The syntax is correct

A new cmd instance is used to ensure the tested string will not include any parser added space at the end. The output of the echo command is tested to see if it matches any of the starting strings followed by numbers up to the end. Then it is tested again for a valid number range.

If errorlevel is set, the value does not match the condition and a new value is requested.

If errorlevel is not set, the value is correct.

Answer 3

FINDSTR's regex flavor is extremely limited. It doesn't even support alternation (|), so even very simple problems are going to have very messy solutions. Here's the most compact expression I can come up with:

FINDSTR /R /I "^PCX[1-9][0-9]?$ ^PCX100$ ^GENPRT[1-9][0-9]?$ ^GENPRT100$ ^NETPRT[1-9][0-9]?$ ^NETPRT100$ ^FAXPRT[1-9][0-9]?$ ^FAXPRT100$"

Each space-separated sequence is treated as a separate regex, so this tries to perform up to eight matches on each string it tests. That's not to say it's slow, but it's a pain in the butt to use when you're used to real regexes.

For reference, here's how I would have written that in a serous regex flavor:

^(PCX|((GEN|NET|FAX)PRT))([1-9][0-9]?|100)$

If you have the option of using a different tool (like PowerShell, which uses .NET's very powerful and feature-rich regex flavor), I strongly recommend you do so.