For Each File in Folder processes files twice when they are renamed

Question

I've used a coding practice dozens of times.
Using the Windows Scripting RunTime FileSystemObject, it iterates through each file in a folder, and "does something" to each file.

Code example:

Public Function RestoreOriginalPicNames(pFolderPath As String, pCharsToChop As Byte) As Boolean

Dim objFSO As New FileSystemObject
Dim objFolder As Folder
Dim objFile As File
Dim FileName As String
Dim FileNameNoExt As String
Dim FileNewName As String

Dim FileExt As String

Set objFolder = objFSO.GetFolder(pFolderPath)
For Each objFile In objFolder.Files
    FileName = objFile.Name
    FileExt = GetExtFromFileName(FileName)
    FileNameNoExt = Left$(FileName, Len(FileName) - Len(FileExt) - 1)
    If FileExt = "JPG" Then
        If Len(FileName) > pCharsToChop Then
            FileNewName = Right$(FileName, Len(FileName) - pCharsToChop)
            objFile.Name = FileNewName
            Debug.Print FileNewName
        End If
    End If
    
Next objFile

RestoreOriginalPicNames = True

End Function

For the first time, the collection of files seems to be refreshing itself from the file-system half-way through the loop, so that two files (possibly due to an accidental feature of their name/renamed name) are processed twice.

I thought that, when the compiler hits the For Each File In [Folder], it internally populates a static array from the file-system. In other words, if the code is already in the loop, any subsequent changes to the population of the folder would be ignored.

In this instance two files get renamed, then somehow get picked up again by the For Each so they get processed twice.

The solution seems to be to explicitly populate an array of file names, and then iterate through that array to process the files (leaving the file-system unaddressed after the initial array population).

I'm worried that this code practice isn't bomb-proof, because I use it all over the place.

Answer 1

Try to exclude this line:

objFile.Name = FileNewName

and watch the Debug.Print output. If that list is as expected, I would use the array method, you mention.

Answer 2

objFSO is an object and objFSO.Files is a property which is updated if a new/different file is added even during processing. A files having a different name than existing is considered a new one...

1. The next function is even faster and returns an array of (already filtered) jpg files:

Function getAllFilesNoSubfold(strFold As String, Optional strExt As String = "*.*") As Variant
    Dim arrFiles
    arrFiles = Split(CreateObject("wscript.shell").Exec("cmd /c dir """ & strFold & strExt & """ /b").StdOut.ReadAll, vbCrLf)
    If UBound(arrFiles) = -1 Then Exit Function 'if not respective files (extensions) could not be found
    Debug.Print UBound(arrFiles): arrFiles(UBound(arrFiles)) = "@@##" 'remove the last (empty) array element
    getAllFilesNoSubfold = filter(arrFiles, "@@##", False)            'function return
End Function

2. Your existing function should be adapted in the next way:

Function RestoreOriginalPicNames(pFolderPath As String, arrFls As Variant, pCharsToChop As Byte) As Boolean
  Dim El As Variant, FileName As String, FileNewName
  For Each El In arrFls
    FileName = left(El, Len(El) - 4)
    If Len(FileName) > pCharsToChop Then
        FileNewName = Right$(FileName, Len(FileName) - pCharsToChop)
        Name pFolderPath & El As pFolderPath & FileNewName & ".jpg"
        Debug.Print FileNewName
    End If
  Next El
  RestoreOriginalPicNames = True
End Function

3. This suggested solution can be tested in the next way:

Sub TestRestoreOriginalPicNames()
    Dim folderPath As String: folderPath = "C:\YourFolderPath\" 'take care of ending backslash!
    Dim arrFiles: arrFiles = getAllFilesNoSubfold(folderPath, "*.jpg") 'use wildcard before extension...
    Debug.Print RestoreOriginalPicNames(folderPath, arrFiles, 6)
End Sub

The function can be adapted (it is even simpler) to return files from all subfolders, too. It is even simpler, returning the full name for each file.

But your code has a weakness, I think: It may be happening that the truncated FileNewName be identic with another one and in such a case the code will raise an error. Think about the issue and find a (logical) solution to solve it. If you clearly explain how to treat such a case, I can adapt the code to do it, I think. Depending on your choice, not being too fancy... :)

Please, send dome feedback after testing it.