Getting Run-Time error '91' when trying to connect to SAP

Question

I am working on connecting to the SAP GUI via VBA, but can't figure out how to get the connection established within its own function. This is assuming you have already logged into the SAP GUI. I am receiving the "Object variable or With block variable not set" error.

Here is an example of what works...

Sub runProgram()
    'Connet to SAP."sapguiapp", used to be named "Application" which is an excel keyword
    If Not IsObject(sapguiapp) Then
        Set SapGuiAuto = GetObject("SAPGUI")
        Set sapguiapp = SapGuiAuto.GetScriptingEngine
    End If
    If Not IsObject(Connection) Then
        Set Connection = sapguiapp.Children(0)
    End If
    If Not IsObject(session) Then
        Set session = Connection.Children(0)
    End If
    If IsObject(WScript) Then
        WScript.ConnectObject session, "on"
        WScript.ConnectObject sapguiapp, "on"
    End If

    'Maximize the SAP window
    session.findById("wnd[0]").maximize
    ' Do a whole bunch of other SAP work, now that we're connected
    '....

End Sub

However, I want to split the connection section into its own sub/function to separate it from the actual work. I thought that I could simply create a new function and return 'session' as an object.

This doesn't work:

Sub runProgram()

        'Call the function that connects to SAP
        Dim session As Object
        Set session = ConnectToSAP

        'Maximize the SAP window
        session.findById("wnd[0]").maximize
        ' Do a whole bunch of other SAP work, now that we're connected (JK, we're not...)
        '....
End Sub

Function ConnectToSAP() As Object
   
        'Connet to SAP."sapguiapp", used to be named "Application" which is an excel keyword
        If Not IsObject(sapguiapp) Then
            Set SapGuiAuto = GetObject("SAPGUI")
            Set sapguiapp = SapGuiAuto.GetScriptingEngine
        End If
        If Not IsObject(Connection) Then
            Set Connection = sapguiapp.Children(0)
        End If
        If Not IsObject(session) Then
            Set session = Connection.Children(0)
        End If
        If IsObject(WScript) Then
            WScript.ConnectObject session, "on"
            WScript.ConnectObject sapguiapp, "on"
        End If

End Function

Is there something painfully obvious that I'm missing? I have a few subs that connect to SAP so I'd like to split out the actual connection code. Any tips would be greatly appreciated!

Edit: Note that I didn't copy/paste this from my actual program, so if there is a a small typo I apologize. Please comment letting me know where I screwed up :)

Answer 1

In the ConnectToSAP function you are missing the assignment statement Set ConnectToSAP = session at the end.

Answer 2

I recommend using Option Explicit and correctly declaring your variables.
If you add a reference to sapfewse.ocx (which is located in your SAP installation folder C:\Program Files (x86)\SAP\FrontEnd\SAPgui\sapfewse.ocx) you can even use VBAs intellisense.
If you don't want to add the reference use Object instead of SAPFEWSLib.GuiSession,SAPFEWSLib.GuiConnection and SAPFEWSLib.GuiApplication.

Option Explicit

Function ConnectToSAP() As SAPFEWSELib.GuiSession
   Dim SapGuiAuto As Object
   Dim SapGuiApp As SAPFEWSELib.GuiApplication
   Dim connection As SAPFEWSELib.GuiConnection

   On Error GoTo Err1
   Set SapGuiAuto = GetObject("SAPGUI")
   Set SapGuiApp = SapGuiAuto.GetScriptingEngine
   On Error GoTo Err2
   Set connection = SapGuiApp.Connections(0)
   Set ConnectToSAP = Connection.Sessions(0)
Exit Function

Err1:
   MsgBox "Please launch SAP"
Exit Function
Err2:
   MsgBox "Please login to SAP"
End Function

WScript is a vbscript object and does not exist in vba. Its ConnectObject method is used for event handling, which can be done in VBA without the need for the WScript object, although you do need a class module and declare your session variable WithEvents:
Class Module:

Private WithEvents session As SAPFEWSELib.GuiSession
Private requestCounter As Long

Private Sub session_startRequest(session As SAPFEWSELib.GuiSession)
   requestCounter = requestCounter + 1
End Sub