Gtk.CssProvider in Genie

Question

I'm using Gtk.CssProvider in Genie to add a style to a button and a window.

I do not know how to specify that a style sheet property applies only to the button and another property applies only to the window. I suppose it will look something like this:

var css = "" "
Gtk.Button {background: # FFFF00; }
Gtk.ApplicationWindow {background: green; }
"" "

I have tried several similar things, but none has worked for me. Maybe with set_name?

For now I have only found this solution (bad code but it works):

// compila con valac --pkg gtk+-3.0 nombre_archivo.gs
uses Gtk

init
    new MyApplication( "test.application",
        ApplicationFlags.FLAGS_NONE
        ).run( args )

class MyApplication:Gtk.Application

    construct( application_id:string, flags:ApplicationFlags )
        if !id_is_valid( application_id )
            error( "application id %s is not valid", application_id )
        this.application_id = application_id
        this.flags = flags

    def override activate ()

        var window = new Gtk.ApplicationWindow( this )      
        window.window_position = WindowPosition.CENTER
        window.set_border_width(10)

        var grid = new Gtk.Grid()       

        var boton1 = new Gtk.Button ()      
        boton1.label = "Boton 1"
        boton1.margin = 10

        var boton2 = new Gtk.Button ()      
        boton2.label = "Boton 2"
        boton2.margin = 10      

        var css_b = "* { background: #FFFF00; }"
        var css_w = "* { background: green; }"

        var provider_b = new Gtk.CssProvider()
        var provider_w = new Gtk.CssProvider()

        try
            provider_b.load_from_data(css_b, css_b.length)
            provider_w.load_from_data(css_w, css_w.length)
        except e: GLib.Error
            stderr.printf ("Hoja de estilo no cargada: %s\n", e.message)        

        boton1.get_style_context().add_provider (provider_b, Gtk.STYLE_PROVIDER_PRIORITY_APPLICATION)
        window.get_style_context().add_provider (provider_w, Gtk.STYLE_PROVIDER_PRIORITY_APPLICATION)

        grid.attach(boton1, 0, 0, 2, 1)
        grid.attach_next_to (boton2, boton1, Gtk.PositionType.RIGHT, 2, 1)

        window.add(grid)
        window.show_all()   

EDIT:

The problem is that this works:

var css = """       
* {background: #FFFF00; }       
"""
var provider = new Gtk.CssProvider()
try
    provider.load_from_data(css, css.length)
except e: GLib.Error
    stderr.printf ("Hoja de estilo no cargada: %s\n", e.message)        

Gtk.StyleContext.add_provider_for_screen (
    Gdk.Screen.get_default(),
    provider,
    Gtk.STYLE_PROVIDER_PRIORITY_APPLICATION)    

But this does not work:

var css = """       
GtkButton {background: #FFFF00; }       
"""
var provider = new Gtk.CssProvider()
try
    provider.load_from_data(css, css.length)
except e: GLib.Error
    stderr.printf ("Hoja de estilo no cargada: %s\n", e.message)        

Gtk.StyleContext.add_provider_for_screen (
    Gdk.Screen.get_default(),
    provider,
    Gtk.STYLE_PROVIDER_PRIORITY_APPLICATION)    

Answer 1

Gtk.Button is not the correct selector name.

For versions of GTK+ prior to 3.20 I believe it was GtkButton.

Starting with 3.20 you will see the correct class name in the C documentation at https://developer.gnome.org/gtk3/stable/, under CSS nodes.

Answer 2

SOLVED

The error was missing Gtk.Widget.get_style_context().add_class("string"):

// compila con valac --pkg gtk+-3.0 nombre_archivo.gs
uses Gtk

init
    new MyApplication( "test.application",
        ApplicationFlags.FLAGS_NONE
        ).run( args )

class MyApplication:Gtk.Application

    construct( application_id:string, flags:ApplicationFlags )
        if !id_is_valid( application_id )
            error( "application id %s is not valid", application_id )
        this.application_id = application_id
        this.flags = flags

    def override activate ()

        var window = new Gtk.ApplicationWindow( this )      
        window.window_position = WindowPosition.CENTER
        window.set_border_width(10)
        window.get_style_context().add_class("mi_ventana")

        var grid = new Gtk.Grid()       

        var boton1 = new Gtk.Button ()      
        boton1.label = "Boton 1"
        boton1.margin = 10
        boton1.get_style_context().add_class("boton1") 

        var boton2 = new Gtk.Button ()      
        boton2.label = "Boton 2"
        boton2.margin = 10      
        boton2.get_style_context().add_class("boton2")

        var css = """
        .mi_ventana { background: green; }
        .boton1 { background: #FFFF00; }
        .boton2 { background: red; }
        """

        var provider = new Gtk.CssProvider()

        try
            provider.load_from_data(css, css.length)
        except e: GLib.Error
            stderr.printf ("Hoja de estilo no cargada: %s\n", e.message)        

        Gtk.StyleContext.add_provider_for_screen(
            Gdk.Screen.get_default(),
            provider,
            Gtk.STYLE_PROVIDER_PRIORITY_USER)   

        grid.attach(boton1, 0, 0, 2, 1)
        grid.attach_next_to (boton2, boton1, Gtk.PositionType.RIGHT, 2, 1)

        window.add(grid)
        window.show_all()