How do I decipher an array of hashes?

Question

I totally got this question wrong. Am using the method from TMDB:

 my @results = $search->find(id     => 'tt0114694', source => 'imdb_id');

I thought the output was in JSON format, so that's what confused me, which kept me running in circles because I was looking at it all wrong.

Didn't realize the data below, from Dumper, was the actual hashes the I had to go through.

This is where I am running into a wall, So the data below is a hash with five keys. The fifth key, the I want, contains another array. It is that array I cannot read into. I try dereferencing that into a hash, and that is where I fail.

The code I am trying is:

foreach my $narray (@results){
    print $narray->{"movie_results"};
    my @newarray = $narray->{"movie_results"};

    foreach my $otherarray (@newarray){
        my %innerhash = $otherarray;
        print %innerhash;
        print "\n";
    }
  } 

It will print out an array, but I am unable to read the hash in that array.

p.s. I had to format this output as code, or else it came out with no line breaks.

   $VAR1 = {
              'tv_season_results' => [],
              'tv_results' => [],
              'person_results' => [],
              'tv_episode_results' => [],
              'movie_results' => [
                                   {
                                     'adult' => bless( do{\(my $o = 0)}, 'JSON::PP::Boolean' ),
                                     'vote_average' => '6.8',
                                     'original_title' => 'Tommy Boy',
                                     'vote_count' => 635,
                                     'id' => 11381,
                                     'release_date' => '1995-03-31',
                                     'overview' => 'Party animal Tommy Callahan is a few cans short of a six-pack. But when the family business starts tanking, it\'s up to Tommy and number-cruncher Richard Hayden to save the day.',
                                     'genre_ids' => [
                                                      35
                                                    ],
                                     'title' => 'Tommy Boy',
                                     'video' => $VAR1->{'movie_results'}[0]{'adult'},
                                     'poster_path' => '/g32WbO9nbY5ydpux5hIoiJkLEQi.jpg',
                                     'original_language' => 'en',
                                     'backdrop_path' => '/bZ4diYf7oyDVaRYeWG42Oify2mB.jpg',
                                     'popularity' => '13.945'
                                   }
                                 ]
            };

Answer 1

When dealing with reference, use the same syntax as if you weren't, but replace the name of the variable with a block that returns the reference.

%NAME      -> %{ $ref }           Or just %$ref
$NAME{...} -> ${ $ref }{...}      Although $ref->{...} easier to read.

@NAME      -> @{ $ref }           Or just @$ref
$NAME[...] -> ${ $ref }[...]      Although $ref->[...] easier to read.

Let's give $VAR a better name,

my $response = $VAR1;

This means you want

my $results = $response->{movie_results};
for my $result (@$results) {
   for my $key (keys(%$result)) {
      say "$key: $result->{$key}";
   }
}

See

• perlreftut
• Perl Dereferencing Syntax

Answer 2

%newhash{$newkey} should be $newhash{$newkey}.

Answer 3

You mention that you thought you'd get JSON output, but got something else. The module made a web request for you, received the JSON response, and translated that to a Perl data structure. That Perl version of the JSON is what you see in the dump.

A JSON object turns into a Perl hash, so that's what you see in the top level of the data structure. That's the single thing find returns (more on that in a moment):

Here's what you have, removing the outer foreach loop:

my @newarray = $narray->{"movie_results"};

foreach my $otherarray (@newarray){
    my %innerhash = $otherarray;
    print %innerhash;
    print "\n";
}

The value in $narray->{"movie_results"} is an array reference. All references are scalars, and those scalars point to some data structure. When you assign that scalar to an array, you just end up with a one element array that's the same reference. Instead, you can

my $movie_results = $narray->{"movie_results"};

You then dereference that reference to treat it as an array:

foreach my $result ( @$movie_results ){ ... }

Or, the v5.24 postfix dereferencing way that I find slightly more pleasing since it reads better, especially when you skip the intermediate variable:

foreach my $result ( $movie_results->@* ){ ... }

foreach my $result ( $narray->{"movie_results"}->@* ){ ... }

That thing in $result is another hash reference.

References and data structures are about half of the content of Intermediate Perl, but there is also the Perl data structures cookbook (perldsc).

Improving your question a bit

You can help us a lot by showing us a complete, working demonstration of your problem. Here's what I cobbled together:

use v5.10;

use TMDB;
use Data::Dumper;

my $tmdb = TMDB->new( apikey => $ENV{TMDB_API_KEY} );
my @results = $tmdb->search->find(
    id     => 'tt0114694',
    source => 'imdb_id'
    );

say Dumper( \@results );

There was a question about the results of find. The documentation example shows it returning a list (well, the result being assigned to a named array, which implies that), but there's not actual documentation for find. It returns the decoded JSON from the response. Assigning it to a scalar (which will be a reference) works just fine too:

my $result = $tmdb->search->find(
    id     => 'tt0114694',
    source => 'imdb_id'
    );

say Dumper( $results );

The return value comes from TMDB::Sesssion::talk(), which is just this (or the empty list):

return $self->json->decode(
    Encode::decode( 'utf-8-strict', $response->{content} ) ); 

That's not a big deal. That just means you don't need the outer foreach. That's not on you because the example in the docs tells you to do exactly what you did.

Now a better program

Putting all that together, here's a simple program pared down to just what you need:

use v5.10; 
use TMDB;

my $tmdb = TMDB->new( apikey => $ENV{TMDB_API_KEY} );
my $result = $tmdb->search->find(
    id     => 'tt0114694',
    source => 'imdb_id'
    );

foreach my $item ( $result->{movie_results}->@* ) {
    say "Title: $item->{title}";
    }

Ref aliasing

There's an experimental feature called ref aliasing that lets you assign a reference to a reference of a named variable. It's an alias, so you can access and change the same data, just with a named variable. Something this is handy when you don't like

use v5.10;

use TMDB;
use experimental qw(refaliasing);

my $tmdb = TMDB->new( apikey => $ENV{TMDB_API_KEY} );

# response is a hash ref, so ref alias to a named hash
\my %result = $tmdb->search->find(
    id     => 'tt0114694',
    source => 'imdb_id'
    );

# the part you want is an array ref, so alias that
\my @movie_results = $result{movie_results};

# each item in the array is a hash ref, so alias those too
foreach \my %item ( @movie_results ) {
    say "Title: $item{title}";
    }