How many Instruction cycles will this instructions take?

Question

If i'm not wrong ldrb r3, [r1], #1 will take 3 instruction cycles, and similarly add r4, r1, #2 will take 1 instruction cycles not discussing the interlock delays here, but i'm confused how many cycles will cmp r4, r3 takes?

Note that: It's ARM ASSEMBLY with ARM9TDMI pipeline timings.

Answer 1

You question is similar and uses similar code as your classmate,

The loop core is,

        ldrb    r3, [r1], #1    ; 3 cycles
        eor     r3, r3, r2      ; 1 cycle
        strb    r3, [r0], #1    ; 1 cycle
        cmp     ip, r0          ; 1 cycle
        bne     .L3             ; 3 cycles

• ldrb, eor r3,r3,r2 is an interlock similar to figure 7.2 and requires two interlock cycles.
• str and cmp are single cycles.
• bne is three cycles.

See section 2.2 for the pipeline stages. It is taking approximately nine cycles. Sections are from the ARM9TDMI TRM.

---

  ldmia  [r1], {r4,r5,r6,r7,r8,r9,r10,r11}  # 3 cycle
  eor    r4,r4,r2   # 1 cycle
  eor    r5,r5,r2   # 1 cycle
  eor    r6,r6,r2   # 1 cycle
  eor    r7,r7,r2   # 1 cycle
  eor    r8,r8,r2   # 1 cycle
  eor    r9,r9,r2   # 1 cycle
  eor    r10,r10,r2   # 1 cycle
  eor    r11,r11,r2   # 1 cycle
  stmia  [r0], {r4,r5,r6,r7,r8,r9,r10,r11}  # 1 cycle

This is 12 cycles for a transfer of 32 bytes, so it is approximately 24 times as fast. Using R4 first is beneficial as per figure 7-4.

---

This alternate loop will take even longer at 13 cycles.

invert:  
  ldrb r5, [r1], #1  ; 3 cycles
  eor r5, r5, r2     ; 1 cycle
  strb r5, [r0], #1  ; 1 cycle
  add r4, r4, #1     ; 1 cycle
  cmp r4, r3         ; 1 cycle
  bxge lr            ; 3 cycles
  b invert           ; 3 cycles

This modification gives 9 cycles, the same as gcc,

invert:  
  ldrb r5, [r1], #1  ; 2 cycles
  add r4, r4, #1     ; 1 cycle
  eor r5, r5, r2     ; 1 cycle
  strb r5, [r0], #1  ; 1 cycle
  cmp r4, r3         ; 1 cycle
  blt invert         ; 3 cycles
  bx  lr             ; 0 cycles, not in loop

However, it is one more instruction.