how to connect to a NIC card or network adapter knowing its IP address?

Question

Say I have two NIC or adapter card on my system and also I found their IP address through the following code:

procedure TForm4.RetrieveLocalAdapterInformation(strings: Tmemo);
var
   pAdapterInfo, pTempAdapterInfo: PIP_ADAPTER_INFO;
   AdapterInfo: IP_ADAPTER_INFO;
   BufLen: DWORD;
   Status: DWORD;
   strMAC: String;
   i: Integer;
begin
   strings.Clear;

   BufLen:= sizeof(AdapterInfo);
   pAdapterInfo:= @AdapterInfo;

   Status:= GetAdaptersInfo(nil, BufLen);
   pAdapterInfo:= AllocMem(BufLen);
   try
Status:= GetAdaptersInfo(pAdapterInfo, BufLen);

if (Status <> ERROR_SUCCESS) then
  begin
    case Status of
      ERROR_NOT_SUPPORTED:
        strings.lines.Add('GetAdaptersInfo is not supported by the operating ' +
                    'system running on the local computer.');
      ERROR_NO_DATA:
        strings.lines.Add('No network adapter on the local computer.');
    else
        strings.Lines.Add('GetAdaptersInfo failed with error #' + IntToStr(Status));
    end;
    Dispose(pAdapterInfo);
    Exit;
  end;

while (pAdapterInfo <> nil) do
  begin
    strings.Lines.Add('Description: ' + pAdapterInfo^.Description);
    strings.lines.Add('Name: ' + pAdapterInfo^.AdapterName);

    strMAC := '';
    for I := 0 to pAdapterInfo^.AddressLength - 1 do
        strMAC := strMAC + '-' + IntToHex(pAdapterInfo^.Address[I], 2);

    Delete(strMAC, 1, 1);
    strings.lines.Add('MAC address: ' + strMAC);
    strings.lines.Add('IP address: ' + pAdapterInfo^.IpAddressList.IpAddress.S);
    strings.lines.Add('IP subnet mask: ' + pAdapterInfo^.IpAddressList.IpMask.S);
    strings.lines.Add('Gateway: ' + pAdapterInfo^.GatewayList.IpAddress.S);
    strings.lines.Add('DHCP enabled: ' + IntTOStr(pAdapterInfo^.DhcpEnabled));
    strings.lines.Add('DHCP: ' + pAdapterInfo^.DhcpServer.IpAddress.S);
    strings.lines.Add('Have WINS: ' + BoolToStr(pAdapterInfo^.HaveWins,True));
    strings.lines.Add('Primary WINS: ' + pAdapterInfo^.PrimaryWinsServer.IpAddress.S);
    strings.lines.Add('Secondary WINS: ' + pAdapterInfo^.SecondaryWinsServer.IpAddress.S);

    pTempAdapterInfo := pAdapterInfo;
    pAdapterInfo:= pAdapterInfo^.Next;
  if assigned(pAdapterInfo) then Dispose(pTempAdapterInfo);
end;
finally
Dispose(pAdapterInfo);
end;
end;

How do I connect to or direct all of my network traffic through specific NIC or network adapter card?

I was able to accomplish this with the following code on Windows 7, but this code won't run on Windows 10. It keeps raising Access Denied message when the program is run as a user but not when it is run as administrator. However, as administrator my program won't run normally but only as a background process on Windows 10....

procedure TDXCommdlg.GetConnectionList(Strings,IdList: TStrings);
var
   pEnum: IEnumVariant;
   vNetCon: OleVARIANT;
   dwRetrieved: Cardinal;
   pUser: NETCONLib_TLB.PUserType1;
   NetCon : INetConnection;
begin
   Strings.Clear;
   IdList.Clear;
   pEnum := (NetSharingManager1.EnumEveryConnection._NewEnum as IEnumVariant);
   while (pEnum.Next(1, vNetCon, dwRetrieved) = S_OK) do
   begin
        (IUnknown(vNetCon) as INetConnection).GetProperties(pUser);
        NetCon := (IUnknown(vNetCon) as INetConnection);

 if (pUser.Status in [NCS_CONNECTED,NCS_CONNECTING])//remove if you want disabled NIC cards also
 and (pUser.MediaType in [NCM_LAN,NCM_SHAREDACCESSHOST_LAN,NCM_ISDN] )
 and (GetMacAddress(GuidToString(pUser.guidId))<>'' ) then
 begin
   //we only want valid network cards that are enabled
   Strings.Add(pUser.pszwName);
   IdList.Add(GuidToString(pUser.guidId));
 end;
 end;
end;

function TDXCommdlg.GetMacAddress(CardID: string): String;
var
   Reg: TRegistry;
   KeyValues: TSTringList;
   i: integer;
   CardInstanceID,CardAddress: string;
begin
   Result := '';
   Reg := TRegistry.Create;
   KeyValues := TStringList.Create;
   try
      Reg.RootKey:=HKEY_LOCAL_MACHINE;
      if Reg.OpenKey(MacLocation,false) then
      begin
      Reg.GetKeyNames(KeyValues);
      Reg.CloseKey;

      for i := 0 to KeyValues.Count-1 do
         if reg.OpenKey(MacLocation+'\'+KeyValues[i],false) then
         begin
             CardInstanceID := Reg.ReadString('NetCfgInstanceId');
             CardAddress := Reg.ReadString('NetworkAddress');
             Reg.CloseKey;

             if CardInstanceID = CardId then
             begin
                if CardAddress='' then CardAddress := 'Hardware';
                   Result := CardAddress;
                break;
             end;
         end;
     end;
     finally
     Reg.Free;
     KeyValues.Free;
   end;
 end;

 procedure TDXCommdlg.ResetNIC(const aConnection: string);
 var
    pEnum: IEnumVariant;
    vNetCon: OleVARIANT;
    dwRetrieved: Cardinal;
    pUser: NETCONLib_TLB.PUserType1;
 begin
    enabled := false;
    try
    pEnum := (NetSharingManager1.EnumEveryConnection._NewEnum as IEnumVariant);
    while (pEnum.Next(1, vNetCon, dwRetrieved) = S_OK) do
    begin
        (IUnknown(vNetCon) as INetConnection).GetProperties(pUser);
        if pUser.pszwName = aConnection then
        begin
           (IUnknown(vNetCon) as INetConnection).Disconnect;
           (IUnknown(vNetCon) as INetConnection).Connect;
           sleep(2000);
           break;
        end;
    end;
    finally
    enabled := true;
 end;
 end;

UPDATE Access Denied is raised by the following line from above and then this procedure quits. It doesn't go any further.

pEnum := (NetSharingManager1.EnumEveryConnection._NewEnum as IEnumVariant);

Answer 1

It sounds as though the library that you use requires elevated rights. Nothing significant has changed in Windows 10 regarding UAC. If your program is running elevated it will succeed. It fails when it is not elevated. So your problem would appear to be that you are failing to execute elevated.

Since your program requires elevation make sure that you manifest that. Add the requireAdministrator option to your application manifest.

You request write access to HKLM which will not be granted for standard user. Call OpenKeyReadOnly rather than OpenKey. There's no point asking for write access when you are only reading.