How to draw TGPGraphics contents onto a Canvas

Question

I'm trying to copy the contents of the following TGPGraphics onto a Canvas but it doesn't work. What am I missing here?

function DrawGlyph(bm: TObject; Canvas: TCanvas; X, Y: Integer): Integer;
var
  O: TGPBitmap;
  G: TGPGraphics;
begin
  if (bm is TGPImage) then
  begin
    O := TGPBitmap.Create(16, 16, PixelFormat32bppARGB);
    try
      G := TGPGraphics.Create(O);
      try
        G.SetCompositingMode(CompositingModeSourceCopy);
        G.SetInterpolationMode(InterpolationModeHighQualityBicubic);
        G.SetPixelOffsetMode(PixelOffsetModeHighQuality);
        G.SetSmoothingMode(SmoothingModeHighQuality);
        G.DrawImage(TGPImage(bm), 0, 0, O.GetWidth, O.GetHeight);

        BitBlt(Canvas.Handle, X, Y, O.GetWidth, O.GetHeight, G.GetHDC, 0, 0, SRCCOPY);
      finally
        G.Free;
      end;

    finally
      O.Free;
    end;
  end;
end;

Answer 1

You can draw the TGPGraphics onto the Canvas directly with the constructor

TGPGraphics.Create(hdc: HDC)

You also do not need the O: TGPBitmap e.g.:

function DrawGlyph(bm: TObject; Canvas: TCanvas; X, Y: Integer): Integer;
var
  G: TGPGraphics;
begin
  // Result := ???
  if (bm is TGPImage) then
  begin
    Canvas.Lock;
    try
      G := TGPGraphics.Create(Canvas.Handle);
      try
        G.SetCompositingMode(CompositingModeSourceCopy);
        G.SetInterpolationMode(InterpolationModeHighQualityBicubic);
        G.SetPixelOffsetMode(PixelOffsetModeHighQuality);
        G.SetSmoothingMode(SmoothingModeHighQuality);
        G.DrawImage(TGPImage(bm), X, Y, 16, 16);
      finally
        G.Free;
      end;
    finally
      Canvas.Unlock;
    end;
  end;
end;