How to get the multi-level categorization for a specific service ticket?

Question

How do you retrieve the specific multi-level categorization information associated with a specific service ticket? For example, here i want to retrieve "Retail Price" :

I need this information to display it in another screen (ticket search result screen, to display each ticket with its motive and submotive).

I'm still a beginner in SAP CRM development and so far I've only come across ways to get the entire categorization schema and not the specific values associated to the service ticket, or ways to get only the first level category (Motive in this case).

Answer 1

You can get the categories like this:

1. Read service ticket subject

   CALL FUNCTION 'CRM_SUBJECT_READ_OW'
   EXPORTING
     iv_ref_guid              = iv_guid
     iv_ref_kind              = 'A'
   IMPORTING
     et_subject_wrk           = lt_subject_wrk
   EXCEPTIONS
     error_occurred           = 1
     OTHERS                   = 2.
   

2. Get categorization schema GUID

   GET TIME STAMP FIELD DATA(lv_timestamp).
   SELECT SINGLE asp_guid
     FROM crmc_erms_cat_as
     INTO lv_asp_guid
    WHERE asp_id = lt_subject_wrk[ ref_guid = iv_guid ref_kind = 'A' ]-asp_id
      AND val_to >= lv_timestamp AND asp_state = 'R'.
   

3. Reading the categories recursively

   lv_cat_guid_new = lt_subject_wrk[ ref_guid = iv_guid ref_kind = 'A' ]-cat_id.
   DO 5 TIMES. " depending of how many category levels you have
   
     SELECT SINGLE node_guid
       FROM crmc_erms_cat_hi AS hi
       JOIN crmc_erms_cat_ca AS ca ON hi~node_guid = ca~cat_guid
       INTO lv_cat_guid_new
      WHERE ca~cat_id = lv_cat_guid_new
        AND ca~asp_guid = lv_asp_guid.
   
   IF sy-subrc <> 0.
     EXIT.
   ENDIF.
   
   ls_hier_query-tree_guid = lv_asp_guid.
   ls_hier_query-tree_type = c_tree_type_cat.
   ls_hier_query-node_guid = lv_cat_guid_new.
   
   CALL FUNCTION 'CRM_ERMS_CAT_HI_READ'
    EXPORTING
     iv_hier_query           = ls_hier_query
    IMPORTING
     et_hier                  = lt_cat_hi.
   
   ls_categ_cat-cat_hi = lt_cat_hi[ 1 ].
   lv_cat_guid_new         = lt_cat_hi[ 1 ]-pare_guid. "For upper level cat. access
   INSERT ls_categ_cat INTO lt_categ_cat INDEX 1.
   *  exit if root category level reached
   IF ls_cat_hi-pare_guid = ls_cat_hi-tree_guid.
    EXIT.
   ENDIF.
   
   ENDDO.
   

4. Output

   LOOP AT lt_categ_cat INTO ls_categ_cat.
    CASE sy-tabix.
      WHEN 1.
       es_categories-category1 = ls_categ_cat.
      WHEN 2.
       es_categories-category2 = ls_categ_cat.
      WHEN 3.
       es_categories-category3 = ls_categ_cat.
      WHEN 4.
       es_categories-category4 = ls_categ_cat.
      WHEN 5.
       es_categories-category5 = ls_categ_cat.
    ENDCASE.
   ENDLOOP.
   

Note Step 3 can also be implemented through methods of class cl_crm_ml_category_util

• cl_crm_ml_category_util=>get_cat_kids_all (snippet)
• cl_crm_ml_category_util=>get_selected_category_tree (snippet)

P.S. Sorry for late answer :)