How to handle no command-line arguments in D?

Question

The proper parlance for the main() entry point in D is

void main(char[][] args)
{

}

but how would I know if there aren't any arguments passed, given it's an array?

Answer 1

void main(char[][] args)

In modern D, the canonical signature is void main(string[] args), or void main() if your program doesn't need arguments.

but how would I know if there aren't any arguments passed, given it's an array?

Check the array's .length property. If args.length==1, then no arguments have been passed to the program. (Argument 0 is always the program itself, as in C/C++.)

Answer 2

Use string[]:

void main(string[] args) {
  // Check args.length
}

You can also use std.getopt to do further parsing.

Answer 3

As our friends have already said, use string[] args:

import std.stdio;

int main(string[] args) {
  if (args.length == 1) {
    writeln("No arguments given. Aborting execution.");
    return 1;
  }
  writeln(args);
  return 42; // answer to everything
}

If you have a rather complex case of many parameters, I suggest you take a look at the std.getopt module.

Here is an example from std.getopt documentation:

import std.getopt;

string data = "file.dat";
int length = 24;
bool verbose;
enum Color { no, yes };
Color color;

void main(string[] args) {
  auto helpInformation = getopt(
    args,
    "length",  &length,    // numeric
    "file",    &data,      // string
    "verbose", &verbose,   // flag
    "color", "Information about this color", &color);    // enum
  ...

  if (helpInformation.helpWanted) {
    defaultGetoptPrinter("Some information about the program.",
      helpInformation.options);
  }
}