How to make rtmpdump accept an url taken from a file // setlocal's and endlocal's effects on batch variables -

Question

@echo off
setlocal EnableDelayedExpansion
wget --output-document=Content.xml Link
for /f "tokens=1" %%a in ('find "1280x720" Content.xml') do set found=%%a

set Url=!found:~5,-6!
for /f "delims=" %%a in (""!Url!"") do endlocal & set "Url=%%~a"
set Filename=Whatever.mp4

:start
rtmpdump -r %Url% -e -b 60000000 -o C:\Users\User\Desktop\%Filename%

if ERRORLEVEL 2 goto start
if exist Content.xml del Content.xml

wget does its job correctly.

The relevant line is correctly stored in the Url variable.

rtmpdump doesn't work.

Id est, instead of displaying the mp4's data (as INFO:) and starting to download, it says "Starting download at 0.000kB" (expected) and stays there until timeout (not expected). After a while an "ERROR: RTMP_ReadPacket, failed to read RTMP packet header" happens. Then, as per the :start loop, it does the same again and again (or until stopped).

@echo off

set Url=rtmpe://Stuff.mp4

set Filename=Whatever.mp4

:start
rtmpdump -r %Url% -e -b 60000000 -o C:\Users\User\Desktop\%Filename%

if ERRORLEVEL 2 goto start

This (manually inputing the rtmpe line, after reading it from the Content.xml file) works.

Link, User, Stuff and Whatever are obviously placeholders for data that I believe to be irrelevant for the problem at hand.

Worth of notice: setting Url manually in the first file still leads to an error, unless it's done after the endlocal statement.

I believe the issue may lay in how "local" variables are stored, but I have no notion of that.

So, can anyone explain what's going on here and how to fix it?

Answer 1

I do not see any reason for using delayed environment variable expansion in your batch file for this task.

@echo off
wget.exe --output-document=Content.xml Link
for /f "tokens=1" %%a in ('%SystemRoot%\System32\find.exe "1280x720" Content.xml') do set found=%%a

set "Url=%found:~5,-6%"
set "Filename=Whatever.mp4"
set "LoopCount=0"

:Loop
rtmpdump.exe -r %Url% -e -b 60000000 -o "%USERPROFILE%\Desktop\%Filename%"
if not errorlevel 2 goto EndBatch
set /A "LoopCount+=1"
if not "%LoopCount%"=="3" goto Loop

:EndBatch
if exist Content.xml del Content.xml