How to multiply two float variables in masm

Question

How to multiply two float variables in masm, assembly user enters an input as 3.02 and multiply it with 0.008 and then print it

.data 
fin dd 5.0

.code
main proc

fld fin
fmul fin  ;to multiply fin with fin 
fstp dword [eax]   ;cannot mov result in eax
call writefloat

exit 
main EndP
end main

Answer 1

If you want to use the FPU keep in mind that it used a stacked set of registers that can only be loaded from, or saved to, memory.
I assume you can document about the FPU programming model by yourself, either by using the Intel manual 1 or, if you feel nostalgic, by reading this 387 manual from Intel dated 05/26/1987.

The instruction fstp dword [eax] save the content of st(0) at the address denoted by eax. This kind of addressing mode is an indirect addressing mode and it is consistently marked with the use of square brackets in the Intel assembly syntax.
Contrast this with saving st(0) in eax, that should look like fstp eax (no brackets).
Alas, the latter is not supported, probably because the FPU supports 64-bit and 80-bit formats that couldn't, at the time, fit any register.

---

To push data. from memory, into the FPU stack use fld, to pop the registers, into memory, use fstp (or fst if you don't want to pop the stack).
To perform a multiplication use fmul, it comes in a few variant, one of which can operate with a memory operand and store the result directly in st(0).

If you feel paranoid you can use finit at the start of the program, this instruction resets the control registers of the FPU to mark the registers empty.
The OS should start your process with a clean state already.

Here a simple example:

.DATA

  A dd 5.0
  B dq 0.008

  C dd 0            ;Move into a BSS section if the assembler support it

.CODE

  finit              ;For paranoid only

  fld DWORD [A]      ;ST(0) = A
  fmul QWORD [B]     ;ST(0) = ST(0)*B = A*B
  fstp DWORD [C]     ;C = ST(0) = A*B

  mov eax, DWORD [C] ;EAX = C = A*B
  call writefloat

---

As today you can use the vector registers with scalar instructions.
You can find the relevant documentation still in the Intel manual linked previously.

.DATA

  A dd 5.0          ;Use float
  B dd 0.008        ;Use float again, avoid cvtss2sd

  C dd 0            ;Move into a BSS section if the assembler support it

.CODE

 movss xmm0, DWORD PTR [A]    ;xmm0.f[0] = A
 mulss xmm0, DWORD PTR [B]    ;xmm0.f[0] = A * B
 movd eax, xmm0               ;eax = xmm0.f[0] = A * B
                              ;Beware, 1 extra cycle for bypass delay
 call writefloat