How to open an URL in a browser using VBA?

Question

Trying to open a PDF(-website) with a referer which can only be opened with a link-click on the parents page.

By Using

 CreateObject(WinHttp.WinHttpRequest.5.1) 
.setRequestHeader "referer", "https://...“ 

the access works, but I need to open the page in a browser to view the pdf.

Found this:

https://learn.microsoft.com/en-us/previous-versions/windows/internet-explorer/ie-developer/platform-apis/aa752094(v=vs.85)

Syntax: object.Navigate2(URL, Flags, TargetFrameName, PostData, Headers)

(PostData [in, optional] Headers [in, optional])

and tried

 Dim IE As InternetExplorer  
 Set IE = New InternetExplorer 
    
   With IE
    .Navigate2
    https://main...,
    "https://referer..."

No results! Does anyone have a solution? (Just VBA please! Thx)

Answer 1

I believe you provided the wrong Referer URL (and wrong format too, you need to also include Referer: in addition to the Referer URL) to the Headers parameter, try this:

Private Sub Test()
    Dim oIE As InternetExplorer
    Set oIE = New InternetExplorer
        
    With oIE
        .Visible = True
        .navigate "https://www.zvg-portal.de/index.php?button=showAnhang&land_abk=ni&file_id=16396&zvg_id=6467", _
                    headers:="Referer: https://www.zvg-portal.de/index.php?button=showZvg&zvg_id=6467&land_abk=sh"
    End With
    oIE.Quit
    Set oIE = Nothing
End Sub 

Answer 2

Upvoted Raymond's as very handy to know.

If you want to do the long way you would interact with the dropdowns as follows. Once results are generated, click the links to the pdfs. Note that the first dropdown has an onchange event which takes the value in the select as argument.

Option Explicit

Public Sub ClickDownloads()
    Dim ie As SHDocVw.InternetExplorer, html As MSHTML.HTMLDocument

    Set ie = New SHDocVw.InternetExplorer: Set html = New MSHTML.HTMLDocument

    With ie
        .Visible = True
        .Navigate2 "https://www.zvg-portal.de/index.php?button=Termine suchen"
 
        While .Busy Or .readyState <> READYSTATE_COMPLETE: DoEvents: Wend
    
        Dim evt As Object
        
        Set evt = .document.createEvent("HTMLEvents")
        evt.initEvent "onchange", True, False
        
        .document.querySelector("[value='ni']").Selected = True
        .document.parentWindow.execScript "updateAmtsgericht('ni');"
        .document.querySelector("[value='P2411']").Selected = True
        .document.querySelector("[type=submit]").Click
        
        While .Busy Or .readyState <> READYSTATE_COMPLETE: DoEvents: Wend
         
        Dim linkNodes As Object, i As Long
         
        Set linkNodes = .document.querySelectorAll("td:last-child a")
        
        For i = 0 To linkNodes.Length - 1
         
            linkNodes.Item(i).Click
            'Do something. Interact with save as dialogue to save. May also want to loop windows to close new tabls that were opened.
        Next
         
        Stop
 
        .Quit
    End With

End Sub