How to plot line only on first value of crossover condition met in Pine Script

Question

I need help in Pine script coding, i want to plot the first crossover value alone not entire series of values for whole day. so if crossover condition is true for 1st or 2nd or 3rd or n times, i need to plot the line from the first condition met to end of day and ignore 2nd or 3rd or 4th or nth series values to plot. how to do it? and i don't want to use line.new() since i want to backtest in tradingview.com, for historical bars i want to use Plot(). so kindly help me with the code.

Strategy im trying: Added 30pts above from 5mins High-Low, if 5 mins candle crossover the 30pts at first time from High need to plot line, ignore if condition met again in a day.

`
//@version=5
indicator(title="Crossover", shorttitle="Crossover", overlay=true)

//*5Mins High Low calculation*//
inputMax = input(5, title= "ORB total time (minutes)")
sess = input("0915-0920", title="Session Time") 
t = time(timeframe.period, sess + ":1234567")
hide = timeframe.isintraday and timeframe.multiplier <= inputMax
is_newbar(res) => ta.change(time(res)) != 0
in_session = not na(t)
is_first = in_session and not in_session[1]
orb_high = float(na)
orb_low = float(na)
if is_first
    orb_high := high
    orb_low := low
else
    orb_high := orb_high[1]
    orb_low := orb_low[1]
if high > orb_high and in_session
    orb_high := high
if low < orb_low and in_session
    orb_low := low
plot(hide ? orb_high : na , style=plot.style_line, color=orb_high[1] != orb_high ? na : color.green , title="ORB High", linewidth=3)
plot(hide ? orb_low : na , style=plot.style_line, color=orb_low[1] != orb_low ? na : color.red, title="ORB Low", linewidth=3)


//*Crossover condition*//
var Up = 0.0
Up := orb_high + 30
var b_i = 0.0
cross_over_happened = if(ta.crossover(close, Up)) and barstate.isconfirmed
    1
else
    0
b_i := ta.valuewhen(cross_over_happened, close, 0)
plot(b_i, color = color.black, linewidth = 2)
`

the above code will plot whenever condition met, but i need to plot only the first value of crossover condition, not for entire series. Kindly help with the code.

Answer 1

I would go about this in a slightly different way (which is very close to what you have done). I would add a bool that will check if a cross already happened today, and will change the value of b_i only when the cross and the new bool are true.

First set the variables that we're going to need:

var float orb_high = na
var float orb_low = na
var bool already_had_crossover_today = false
var float b_i = na

Second, reset those variables on each new day:

if ta.change(time("D"))
    orb_high := high
    orb_low := low
    already_had_crossover_today := false
    b_i := na

Third, we'll check for the crossover, regardless if it's the first one on the day or not:

Up = orb_high + 30
cross_over_happened = ta.crossover(close, Up)

And lastly, we'll check if we had a crossover and during the day a crossover hasn't happened yet:

if cross_over_happened and not already_had_crossover_today
    b_i := close
    already_had_crossover_today := true

Than we can just use plot, and for better visualization use the style parameter:

plot(b_i, style = plot.style_linebr)