How to rename files with list of names using command prompt?

Question

I have a folder with multiple files. All files names looks like:

"1 зелен.doc"
"2 будда.doc"
"3 конфуций.doc"

All files are in order of first number that are in the beginning of the names. I have a list of filenames, that contains in text file. Each line in the text file is also in order. So, the first line is the name for the first file name, the second line is second file name and so on. How to rename files using command prompt?

Thank you very much!

Answer 1

@echo off
setlocal EnableDelayedExpansion

rem The list of filenames will be read from redirected Stdin
< filenames.txt (

   rem Process the files via FOR command
   for %%a in (*.*) do (

      rem Read the next name from the list
      set /P name=

      rem Rename the file
      ren "%%a" "!name!"

   )
)

Answer 2

Assuming the list of filenames corresponds to a directory listing exactly, you can do it by shoving the contents of your text file into an array, a directory listing into another array, then looping through both arrays with for /L like this:

@echo off
setlocal enabledelayedexpansion

set "count=0"

for /f "delims=" %%I in (textfile.txt) do (
    set "to[!count!]=%%I"
    set /a count+=1
)

set "count=0"

for %%I in (*.doc) do (
    set "from[!count!]=%%I"
    set /a count+=1
)

for /L %%I in (0,1,!count!) do (
    if exist "!from[%%I]!" (
        echo ren "!from[%%I]!" "!to[%%I]!"
    )
)

Save this script to a .bat file and run it. Remove the echo before ren when you are satisfied your result will be what you intend.

Answer 3

it has been a long time since the question, but maybe it could be useful for someone (like me, that today 2020, I was trying to do the same). You can create a Sheet on Excel with first column "Rem" second with the name of the file and third with the new name for each file. Then you copy the three columns and paste in the CMD (MS-DOS command prompt) and you are done.

Excel should be like this:

Rem old-name.txt new-name.txt

You have to be VERY CAREFUL that neither old names nor new names can have spaces, what I did is to replace (with any program to change names) spaces with "--" and then put them back.

I hope this could be useful for someone.