How to turn a string which should be split on the <space> an turned into an array of objects in mulesoft

Question

I am trying to turn a string which should be split on the basis of space and turned into an array of objects. Please help me how can I form it.

Input

field: YYC:16:26 YVR:16:03 YEG:13:43

Output Expected

"details" : [     
  {
    "field" : "YYC",         
    "time" : "16:26"     
   },  
   {
      "field" : "YVR",
      "Time" : "16:03"     
    }, 
    {
      "field" : "YEG",
      "Time" : "13:43"     
    }
]

Answer 1

A slight twist to what Karthik posted:

%dw 2.0
output application/json
import * from dw::core::Arrays
var test= "YYC:16:26 YVR:16:03 YEG:13:43" splitBy  " "
---
details: test map 
{
    "field": ($ splitBy ":")[0],
    "Time":  drop(($ splitBy ":"),1)joinBy ":"
}

Answer 2

you need to split first by sapce and then need to break the remaining string as below

%dw 2.0
output application/json
var test= "YYC:16:26 YVR:16:03 YEG:13:43" splitBy  " "
---
details: test map ((item, index) -> 
{
    "field": item[0 to 2],
    "Time": item [4 to -1]
})

Answer 3

Another way of approach similar to Anurag's solution

DW

%dw 2.0
output application/json
var test= "YYC:16:26 YVR:16:03 YEG:13:43" splitBy  " "
---
details: test map ((item, index) -> 
{
    "field": (item splitBy ":")[0],
    "Time": (item splitBy ":")[1 to -1] joinBy ":"
})

Output

{
  "details": [
    {
      "field": "YYC",
      "Time": "16:26"
    },
    {
      "field": "YVR",
      "Time": "16:03"
    },
    {
      "field": "YEG",
      "Time": "13:43"
    }
  ]
}