How would I return a list that takes two lists and associates them with the contents in that list together in plait language for Racket?

Question

I'm working on a problem that has me using Racket with plait language and I'm trying to get a program that takes two lists and associate them together like this. I am relatively new to Racket and the plait language.

'(a b c d) and '(1 2 3 4)

Together they should output:

'((make-assoc 'a 1) (make-assoc 'b 2) (make-assoc 'c 3) (make-assoc 'd 4)))

This is what I have defined so far:

#lang plait
(define-type Associate
  (assoc [name : Symbol]
         [values : Number]))

(define (make-assoc [names : (Listof Symbol)] [values : (Listof Number)]): (Listof assoc)
  (map (lambda (name value) (assoc name value)) names values))

(test (make-assoc '(a b c d) '(1 2 3 4))
      '((make-assoc 'a 1) (make-assoc 'b 2) (make-assoc 'c 3) (make-assoc 'd 4)))
(test (make-assoc '(t a c o tuesday) '(0 1 34 1729 42))
      '((make-assoc 't 0) (make-assoc 'a 1) (make-assoc 'c 34) (make-assoc 'o 1729) (make-assoc 'tuesday 42)))

I tried to get somewhere coming up stuff for make-assoc but I am having trouble with syntax and I guess I can't use map or lambda because make-assoc is already the identifier. So maybe I could use append in some way?

Answer 1

First of all, the type is Associate, not assoc.
assoc is the name of its only variant, and is used to construct values of the Associate type.

> assoc
- (Symbol Number -> Associate)
#<procedure:assoc>
> (assoc 'hello 1234)
- Associate
(assoc 'hello 1234)

So you should have

(define (make-associate [names : (Listof Symbol)] [values : (Listof Number)]): (Listof Associate)
...

(You also need to rename it, as make-assoc is already taken by the "machinery".)

Second, the type of map is

(('a -> 'b) (Listof 'a) -> (Listof 'b))

so it takes a one-argument function and one list and produces a list.
You want map2, which has the type

(('a 'b -> 'c) (Listof 'a) (Listof 'b) -> (Listof 'c))

So,

(define (make-associate [names : (Listof Symbol)] [values : (Listof Number)]): (Listof Associate)
  (map2 (lambda (name value) (assoc name value)) names values))

Third, quoting "suspends" evaluation; '(a b) is not the same as (list a b) – the former is a list of the symbols a and b while the latter is a list of the values those symbols are bound to.

> (define a 1)
> a
- Number
1
> 'a
- Symbol
'a
> (list a)
- (Listof Number)
'(1)
> '(a)
- (Listof Symbol)
'(a)

So you want to use list rather than ' in your test cases.
You also use assoc, not make-assoc, to create values of the Associate type.

In summary:

(test (make-associate '(a b c d) '(1 2 3 4))
      (list (assoc 'a 1)
            (assoc 'b 2)
            (assoc 'c 3)
            (assoc 'd 4)))
(test (make-associate '(t a c o tuesday) '(0 1 34 1729 42))
      (list (assoc 't 0)
            (assoc 'a 1)
            (assoc 'c 34)
            (assoc 'o 1729)
            (assoc 'tuesday 42)))

And now,

good (make-associate '(a b c d) '(1 2 3 4)) at line 10
  expected: (list (assoc 'a 1) (assoc 'b 2) (assoc 'c 3) (assoc 'd 4))
  given: (list (assoc 'a 1) (assoc 'b 2) (assoc 'c 3) (assoc 'd 4))

good (make-associate '(t a c o tuesday) '(0 1 34 1729 42)) at line 14
  expected: (list (assoc 't 0) (assoc 'a 1) (assoc 'c 34) (assoc 'o 1729) (assoc 'tuesday 42))
  given: (list (assoc 't 0) (assoc 'a 1) (assoc 'c 34) (assoc 'o 1729) (assoc 'tuesday 42))