I'm having trouble with multiple for loop stacking in vb.net

Question

So I've tried all kinds of things. I'm going to post what I have first and then go over the additional stuff I've tried. I know I've got my logistics messed up in some kind of way, but after trying like 10 different things I'm at a loss. This is what I've got currently:

Public Shared Function secureDelete(ByVal dir As String, ByVal toWrite As Integer, ByVal delType As SearchOption) As List(Of String)
currentNum = 0
totalFiles = Directory.GetFiles(dir).Length
Try
    For Each f As String In Directory.GetFiles(dir, "*.*", delType)
        If File.Exists(f) Then
            File.SetAttributes(f, FileAttributes.Normal)
            Dim sectors As Double = Math.Ceiling(New FileInfo(f).Length / 512)
            Dim b = New Byte(511) {}
            Dim rng As RandomNumberGenerator = RandomNumberGenerator.Create()
            Dim inputStream As New FileStream(f, FileMode.Open)
            For currentPass As Integer = 0 To toWrite - 1 Step 1
                'If currentPass < toWrite Then
                Debug.WriteLine("C1: " & currentPass & " - T1: " & toWrite)
                    inputStream.Position = 0
                    For sectorsWritten As Integer = 0 To sectors - 1 Step 1
                    'If sectorsWritten < sectors Then
                    Debug.WriteLine("C: " & sectorsWritten & " - T: " & sectors)
                            rng.GetBytes(b)
                            Debug.WriteLine(b.ToString())
                            inputStream.Write(b, 0, b.Length)
                    'End If
                Next
                'End If

            Next
            inputStream.SetLength(0)
            inputStream.Close()
            rng.Dispose()
            Dim dt As New DateTime(2099, 1, 1, 0, 0, 0)
            File.SetCreationTime(f, dt)
            File.SetLastAccessTime(f, dt)
            File.SetLastWriteTime(f, dt)
            File.SetCreationTimeUtc(f, dt)
            File.SetLastAccessTimeUtc(f, dt)
            File.SetLastWriteTimeUtc(f, dt)
            File.Delete(f)
            fileList.Add("OK: " & f)
            Debug.WriteLine(f)
            currentProg = updateProgress(currentNum + 1)



        End If


    Next
    Return fileList
    currentProg = 0

Catch ex As Exception
    Debug.WriteLine(ex.ToString())
    fileList.Add("ERROR: " & ex.ToString)
    Return fileList
    currentProg = 0
End Try
End Function

Here are the properties you'll see referenced in this snippet:

Private Shared Property totalFiles As Integer = 0
Private Shared Property currentNum As Integer = 0
Public Shared Property currentProg As Integer = 0
Public Shared Property fileList As List(Of String)

The point of this function is to generate garbage data and overwrite all files individually with said garbage data, then delete the file. You can see where I commented off some If statements. At first I thought those were neccessary, but after staring at it for a while it seemed redundant, so I removed it. Same results. Then I realized I had my byte array declared wrong (Dim b As Byte(511), or at least, maybe?) so I changed that. Same results. It seems like my code is getting stuck in my For loops. I don't know why. Obviously it has to do with the way it's being counted, but I've also tried: does not equal on the If statements, no Step on the For statements, plus equals instead of - 1, and probably some other stuff. I've literally been trying to do this all day. I'm totally lost. It has to be something with the For loops right? I haven't done any coding in probably 10 years so I'm extremely rusty and trying to get back into it a little bit. Any insights would be appreciated. This is the error I'm getting, by the way:

Answer 1

OK your code is mostly fine. I have tweaked it to work below.

Changes:

• Factored out a method to scrub a single file and then call that from within the loop. That made it easier to debug whether there were problems with the file scrubbing code, or the external loop.
• Removed the use of global variables. This also makes it easier to debug
• Disposed variable inputStream. I suspect this was what was wrong with your code - without disposing the stream, it is still open and then File.Delete() would fail.
• Moved Try-Catch so it is per-file. This allows the code to tell you which files succeeded and which failed.

Code:

Imports System.IO
Imports System.Security.Cryptography

Module Program
  Sub Main(args As String())
    Dim directory = "C:\Junk\JunkTest"
    Dim results = secureDelete(directory, 2, SearchOption.TopDirectoryOnly)
    For Each result In results
      Console.WriteLine(result)
    Next
    Console.WriteLine("FINISHED")
    Console.ReadKey()
  End Sub

  Public Function secureDelete(dir As String, toWrite As Integer, delType As SearchOption) As List(Of String)
    Dim output As New List(Of String)
    For Each f As String In Directory.GetFiles(dir, "*.*", delType)
      output.Add(secureDeleteFile(f, toWrite))
    Next f
    Return output
  End Function


  Public Function secureDeleteFile(filename As String, toWrite As Integer) As String
    Try '<< Added
      File.SetAttributes(filename, FileAttributes.Normal)
      Dim sectors = Math.Ceiling(New FileInfo(filename).Length / 512)
      Dim b = New Byte(511) {}
      Dim rng = RandomNumberGenerator.Create
      Dim inputStream = New FileStream(filename, FileMode.Open)
      For currentPass As Integer = 0 To toWrite - 1
        Debug.WriteLine("C1: " & currentPass & " - T1: " & toWrite)
        inputStream.Position = 0
        For sectorsWritten As Integer = 0 To sectors - 1
          Debug.WriteLine("C: " & sectorsWritten & " - T: " & sectors)
          rng.GetBytes(b)
          Debug.WriteLine(BitConverter.ToString(b)) '<< fixed to show hex values of byte array
          Debug.WriteLine(b.Length)
          inputStream.Write(b, 512 * sectorsWritten, b.Length) '<< fixed sector start
        Next
      Next
      inputStream.SetLength(0)
      inputStream.Close()
      inputStream.Dispose() '<< added
      rng.Dispose()
      Dim dt As New DateTime(2099, 1, 1, 0, 0, 0)
      File.SetCreationTime(filename, dt)
      File.SetLastAccessTime(filename, dt)
      File.SetLastWriteTime(filename, dt)
      File.SetCreationTimeUtc(filename, dt)
      File.SetLastAccessTimeUtc(filename, dt)
      File.SetLastWriteTimeUtc(filename, dt)
      File.Delete(filename)
      Return "OK: " & filename
    Catch ex As Exception
      Return "ERROR: " & ex.Message
    End Try
  End Function
End Module