How to export a Kolmogorov–Smirnov?

Question

I have made a two-sample Kolmogorov–Smirnov test. I want a way to export this into a nice graph. I know simple OLS regressions have outreg2, but is there an equivalent I can use for the KS test?

Answer 1

Here is some code for the two-group case. The code for the two-variable case is necessarily different in part, but I think easier.

sysuse auto, clear

* redundant in this case, but not in all others 
drop if missing(mpg, foreign)

sort mpg foreign
cumul mpg if foreign, gen(cdf_foreign)
cumul mpg if !foreign, gen(cdf_domestic)
foreach v of var cdf* {
    replace `v' = `v'[_n-1] if missing(`v')
}
foreach v of var cdf* {
    bysort mpg (`v') : replace `v' = `v'[_N]
}
foreach v of var cdf* {
    replace `v' = 0 if missing(`v') 
}

gen diff = abs(cdf_domestic - cdf_foreign)
sort diff 
replace diff = . if diff != diff[_N]

set scheme s1color 

line cdf_foreign cdf_domestic mpg, c(J J) sort color(blue red) ///
|| rspike cdf_foreign cdf_domestic mpg if diff < . , ///
legend(order(2 "Domestic" 1 "Foreign") ring(0) pos(11) col(1)) yla(0 0.25 0.5 0.75 1, ang(h))