Instantiating a SoundFile object within a class in Processing

Question

I am attempting to create an instance of the SoundFile type inside of another class in Processing (the latest version, 3.0a10). I can easily play a sound that is defined outside of a class, as follows:

import processing.sound.*;

SoundFile clickSound;

void setup() {
  size(600, 600);
  clickSound = new SoundFile(this, "bike-passing-by.wav");
}

void draw() {
  clickSound.play();
}

However, I run into trouble when I attempt to create a SoundFile instance from inside a class. A simplified example of this would be:

import processing.sound.*;

SomeSound fx;

void setup() {
  size(600, 600);
  fx = new SomeSound();
}

void draw() {
  fx.play();
}

class SomeSound {
  SoundFile clickSound;

  SomeSound() {
    clickSound = new SoundFile(this, "bike-passing-by.wav");
  }

  void play() {
    clickSound.play();
  }

}

The error I receive is that "The constructor SoundFile(soundTest.SomeSound, String) is undefined". In the Processing reference for SoundFile, it states that the constructor is defined as SoundFile(parent, path). The parent parameter is supposed to be PApplet: typically use "this".

I therefore tried a number of options to replace this line: clickSound = new SoundFile(this, "bike-passing-by.wav");

I tried replacing this with super: clickSound = new SoundFile(super, "bike-passing-by.wav");

and PApplet: clickSound = new SoundFile(PApplet, "bike-passing-by.wav");

but only manage to produce different errors. Any advice on how to fix this would be greatly appreciated.

Answer 1

The error is happening because, like you said, you need access to the PApplet instance that is automatically created for you in your Processing sketch. When you're in another class, the this keyword refers to the instance of that class, not the sketch's PApplet instance.

If your class is inside your main sketch (not in another tab), then you can do this:

import processing.sound.*;

SomeSound fx;

void setup() {
  size(600, 600);
  fx = new SomeSound();
}

void draw() {
  fx.play();
}

class SomeSound {
  SoundFile clickSound;

  SomeSound() {
    clickSound = new SoundFile(NameOfYourSketch.this, "bike-passing-by.wav");
  }

  void play() {
    clickSound.play();
  }

}

The only line you really care about is this one:

clickSound = new SoundFile(NameOfYourSketch.this, "bike-passing-by.wav");

This syntax might look strange, but you can get to the sketch-level this by using NameOfYourSketch.this. Under the hood, this is because your sketch is compiled into a Java class, and classes inside your main sketch window are non-static inner classes of that class.

If your class is in another tab, that approach won't work, because classes in their own tab are compiled into their own top-level non-inner Java classes, so they don't have access to the sketch-level this variable. Instead, you'd have to pass it into the class:

import processing.sound.*;

SomeSound fx;

void setup() {
  size(600, 600);
  fx = new SomeSound(this);
}

void draw() {
  fx.play();
}

class SomeSound {
  SoundFile clickSound;

  SomeSound(PApplet p) {
    clickSound = new SoundFile(p, "bike-passing-by.wav");
  }

  void play() {
    clickSound.play();
  }

}

Notice that the SomeSound constructor takes a PApplet argument, which it can then pass into the SoundFile constructor. To supply that PApplet instance to the SomeSound constructor, you can then use the sketch-level this keyword.

Note that this second approach will work if your class is defined in its own tab or if it's inside the sketch tab, and it's a little less "coupled" with your sketch, so it's probably preferable over the first approach.

Answer 2

import processing.sound.*;

class callerClass{
  SomeSound fx;

  void setup() {
    size(600, 600);
    this.fx = new SomeSound();
  }

  void draw() {
    this.fx.play();
  }
}
class SomeSound {
  SoundFile clickSound;

  SomeSound() {
    clickSound = new SoundFile(this, "bike-passing-by.wav");
  }

  void play() {
    clickSound.play();
  }

}

• In this method instance fx is not destroy so try this method if any problem must comment.