Iterate through the folder and find a particular file

Question

I have written this code to iterate through the folders and exit the function when it finds the ".c" file. Ideally it should return the path of the ".c" file. But its returning empty string.

tval = 1
Function findStlcode(objFSO,fFolder,folderName)
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    Set Folder = objFSO.GetFolder(fFolder)
    Set colfiles = Folder.Files
    For Each objFile In colfiles
        strFilename = objFile.name
        If strcomp(strFilename,folderName & ".c",vbTextCompare) = 0 Then
            findStlcode = fFolder & "\" & folderName & ".c"
            tval = tval + 1
            Exit Function
        End If
    Next
    For Each Subfolder In Folder.SubFolders
        If tval = 1 Then
            xx = findStlcode(objFSO, Subfolder.Path, folderName)
        End If
    Next
End Function

Answer 1

Change the FOR loop contents to below, change xx to findStlcode and it should work

strFilename = objFile.name
If Right(strFilename, 2) = ".c" Then
    findStlcode = fFolder & "\" & strFilename
    tval = tval + 1
    Exit Function
End If

---

Complete code below

tval = 1
Function findStlcode(objFSO,fFolder)
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    Set Folder = objFSO.GetFolder(fFolder)
    Set colfiles = Folder.Files
    For Each objFile In colfiles
        strFilename = objFile.name
        If Right(strFilename, 2) = ".c" Then
            findStlcode = fFolder & "\" & strFilename
            tval = tval + 1
            Exit Function
        End If
    Next
    For Each Subfolder In Folder.SubFolders
        If tval = 1 Then
            findStlcode = findStlcode(objFSO, Subfolder.Path)
        End If
    Next
End Function

---

Calling the Function

Set objFSO = CreateObject("Scripting.FileSystemObject")
Wscript.Echo findStlcode(objFSO, "C:\")

Answer 2

The root cause of your problem is that your function doesn't actually return the path (by assigning it to the function name), as others have already pointed out.

There are, however, some other issues with your implementation that you may want to address:

• You shouldn't use a global variable to keep track of whether a matching file was found or not. The return value of the recursive function calls can be used to the same effect.
• There's no point in passing objFSO if you're going to re-create it with each function call anyway. In practically every case it's better to create a FileSystemObject instance as a global (singleton) object and use that everywhere in your script.
• Pass folder objects instead of path strings, so you don't have to turn the string back into a folder object in the next recursion step.
• If you're going to check for an extension, use the appropriate method to extract the extension from a file name (GetExtensionName).

Something like this would suffice:

Set fso = CreateObject("Scripting.FileSystemObject")

Function findStlcode(fldr)
  Dim f, sf, path

  For Each f In fldr.Files
    If LCase(fso.GetExtensionName(f)) = "c" Then
      path = f.Path
      Exit For
    End If
  Next

  For Each sf In fldr.SubFolders
    If IsEmpty(path) Then path = findStlcode(sf)
  Next

  findStlcode = path
End Function

startFolder = "C:\some\folder"
cfile = findStlCode(fso.GetFolder(startFolder))