itextsharp pdfsmartcopy only returning last page

Question

I have an issue where only the last page of my pdf is stored.

The pdf should be multiple pages long, and this works fine if I just send the pdf to the browser using Response and the mms memory stream, however I need to add it as a pdf to an email and therefore are writing mms to bytes to create a new memorystream when I create my email attachment. This is to get around the closed stream error.

This is my code

 Public Shared Function SendPrePackLabels(ByVal bf_id As String, mail As String) As Boolean
        Dim pars(0) As SqlParameter
        pars(0) = New SqlParameter("@bf_id", SqlDbType.VarChar) With {.Value = bf_id}

        Dim p As String
        Dim reader As PdfReader
        Dim mms As New MemoryStream

        Dim rt() As Byte
        Dim i As Integer = 0

        Using dc As Document = New Document
            Using sc As PdfSmartCopy = New PdfSmartCopy(dc, System.Web.HttpContext.Current.Response.OutputStream)
                dc.Open()
                With SqlHelper.ExecuteDataset(Stiletto.cnStrRMIS, CommandType.StoredProcedure, "BPM_spPrepack_Labels", pars).Tables(0)
                    For Each dr As DataRow In .Rows
                        Dim pdfr As New PdfReader("http://192.168.0.221/template.pdf")
                        Using ms As New MemoryStream
                            Using pdfs As New PdfStamper(pdfr, ms)
                                Dim fields As AcroFields = pdfs.AcroFields
                                fields.GenerateAppearances = True
                                fields.SetField("pono", dr.Item("po_no").ToString)
                                fields.SetField("ref", dr.Item("alt_code").ToString)
                                fields.SetField("colour", dr.Item("colour").ToString)
                                fields.SetField("code", dr.Item("sizerun_hdr_id").ToString)

                                For k As Integer = 1 To dr.Table.Columns.Count - 6
                                    Dim j As Integer = k + 5
                                    fields.SetField("s" & k, dr.Table.Columns(j).ColumnName.ToString)
                                    If dr.Item(dr.Table.Columns(j).ColumnName.ToString).ToString = "" Then
                                        p = "0"
                                    Else
                                        p = dr.Item(dr.Table.Columns(j).ColumnName.ToString).ToString
                                    End If
                                    fields.SetField("p" & k, p)
                                Next
                                fields.SetField("pack", dr.Item("sizerun_hdr_id").ToString)
                                Dim bcfont As BaseFont = BaseFont.CreateFont("http://192.168.0.221/ean.ttf", BaseFont.CP1252, BaseFont.EMBEDDED)
                                fields.SetFieldProperty("barcode", "textfont", bcfont, Nothing)
                                fields.SetFieldProperty("barcode", "textsize", 60.0F, Nothing)


                                Dim mBarcode As String = "219" & dr.Item("sizerun_hdr_id").ToString
                                Dim cLength As Integer = mBarcode.Length

                                Dim zerostoadd As Integer = 12 - cLength
                                Dim digit12barcode As String = mBarcode.PadRight(12, CChar("0"))
                                Dim FinalBarcode As String = returnCheckDigitedBarcode(digit12barcode)
                                fields.SetField("barcode", FinalBarcode)


                                Dim par(1) As SqlParameter
                                par(0) = New SqlParameter("@sizerun_hdr_id", SqlDbType.VarChar) With {.Value = dr.Item("sizerun_hdr_id").ToString}
                                par(1) = New SqlParameter("@ean13", SqlDbType.VarChar) With {.Value = FinalBarcode}

                                SqlHelper.ExecuteScalar(Stiletto.cnStrRMIS, CommandType.StoredProcedure, "BPM_spSizeRunEAN13", par)
                                pdfs.FormFlattening = True
                                ms.Flush()
                            End Using
                            reader = New PdfReader(ms.ToArray)
                            sc.AddPage(sc.GetImportedPage(reader, 1))
                            mms = ms
                        End Using
                    Next
                End With
            End Using
        End Using

        Dim bt() As Byte = mms.ToArray

        Try
            If mail.Length > 0 Then
                Dim eMsg As New MailMessage()

                eMsg.From = New MailAddress("[email protected]")
                eMsg.To.Add(New MailAddress(mail))


                Dim title As String = "<h3>Here are the Prepack Labels.</h3>"

                eMsg.Subject = "Prepack Labels"
                eMsg.Body = "<html>" & title & "</html>"
                eMsg.IsBodyHtml = True

                Dim att As Attachment = New Attachment(New MemoryStream(bt), "Prepack Labels.pdf", "application/pdf")
                eMsg.Attachments.Add(att)

                Dim SMTP1 As New SmtpClient
                SMTP1.Host = "EX"
                SMTP1.Send(eMsg)

                att.Dispose()
            End If
            Return True
        Catch ex As Exception
            Return False
        End Try
       End Function

Answer 1

I'm not sure of your exact problem but I'm pretty sure your life would be easier if you broke you giant function into smaller more specific functions that do only one thing. Also, I really recommend never writing to the raw ASP.Net stream until after you've created a PDF. Instead, always write to a MemoryStream, grab the bytes and do something with them.

The code below break it into four functions. CreatePdf() loops through the database and calls CreateSinglePdf() for each row in the table, merging them with your PdfSmartCopy. SendEmail() is blissfully unaware of iTextSharp completely and just receives a raw array of bytes that is assumed to be a PDF. This is all kicked off by SendPrePackLabels() which is where you'd probably want to also Response.BinaryWrite() your bytes.

Public Shared Function SendPrePackLabels(ByVal bf_id As String, mail As String) As Boolean
    Dim bt = CreatePdf(bf_id)
    Return SendEmail(bt, mail)
End Function
Public Shared Function CreateSinglePdf(dr As DataRow) As Byte()
    Using ms As New MemoryStream
        Using pdfr As New PdfReader("http://192.168.0.221/template.pdf")
            Using pdfs As New PdfStamper(pdfr, ms)
                Dim fields As AcroFields = pdfs.AcroFields
                fields.GenerateAppearances = True
                fields.SetField("pono", dr.Item("po_no").ToString)
                fields.SetField("ref", dr.Item("alt_code").ToString)
                fields.SetField("colour", dr.Item("colour").ToString)
                fields.SetField("code", dr.Item("sizerun_hdr_id").ToString)

                Dim p As String

                For k As Integer = 1 To dr.Table.Columns.Count - 6
                    Dim j As Integer = k + 5
                    fields.SetField("s" & k, dr.Table.Columns(j).ColumnName.ToString)
                    If dr.Item(dr.Table.Columns(j).ColumnName.ToString).ToString = "" Then
                        p = "0"
                    Else
                        p = dr.Item(dr.Table.Columns(j).ColumnName.ToString).ToString
                    End If
                    fields.SetField("p" & k, p)
                Next
                fields.SetField("pack", dr.Item("sizerun_hdr_id").ToString)
                Dim bcfont As BaseFont = BaseFont.CreateFont("http://192.168.0.221/ean.ttf", BaseFont.CP1252, BaseFont.EMBEDDED)
                fields.SetFieldProperty("barcode", "textfont", bcfont, Nothing)
                fields.SetFieldProperty("barcode", "textsize", 60.0F, Nothing)


                Dim mBarcode As String = "219" & dr.Item("sizerun_hdr_id").ToString
                Dim cLength As Integer = mBarcode.Length

                Dim zerostoadd As Integer = 12 - cLength
                Dim digit12barcode As String = mBarcode.PadRight(12, CChar("0"))
                Dim FinalBarcode As String = returnCheckDigitedBarcode(digit12barcode)
                fields.SetField("barcode", FinalBarcode)


                Dim par(1) As SqlParameter
                par(0) = New SqlParameter("@sizerun_hdr_id", SqlDbType.VarChar) With {.Value = dr.Item("sizerun_hdr_id").ToString}
                par(1) = New SqlParameter("@ean13", SqlDbType.VarChar) With {.Value = FinalBarcode}

                SqlHelper.ExecuteScalar(Stiletto.cnStrRMIS, CommandType.StoredProcedure, "BPM_spSizeRunEAN13", par)
                pdfs.FormFlattening = True
            End Using
        End Using

        Return ms.ToArray()
    End Using
End Function
Public Shared Function CreatePdf(ByVal bf_id As String) As Byte()
    Dim pars(0) As SqlParameter
    pars(0) = New SqlParameter("@bf_id", SqlDbType.VarChar) With {.Value = bf_id}


    Using ms As New System.IO.MemoryStream
        Using dc As Document = New Document
            Using sc As PdfSmartCopy = New PdfSmartCopy(dc, ms)
                dc.Open()
                With SqlHelper.ExecuteDataset(Stiletto.cnStrRMIS, CommandType.StoredProcedure, "BPM_spPrepack_Labels", pars).Tables(0)
                    For Each dr As DataRow In .Rows

                        Dim pageBytes = CreateSinglePdf(dr)

                        Using reader = New PdfReader(pageBytes)
                            sc.AddPage(sc.GetImportedPage(reader, 1))
                        End Using
                    Next
                End With
            End Using
        End Using

        Return ms.ToArray()
    End Using
End Function

Public Shared Function SendEmail(bt As Byte(), mail As String) As Boolean
    Try
        If mail.Length > 0 Then
            Dim eMsg As New MailMessage()

            eMsg.From = New MailAddress("[email protected]")
            eMsg.To.Add(New MailAddress(mail))


            Dim title As String = "<h3>Here are the Prepack Labels.</h3>"

            eMsg.Subject = "Prepack Labels"
            eMsg.Body = "<html>" & title & "</html>"
            eMsg.IsBodyHtml = True

            Dim att As Attachment = New Attachment(New MemoryStream(bt), "Prepack Labels.pdf", "application/pdf")
            eMsg.Attachments.Add(att)

            Dim SMTP1 As New SmtpClient
            SMTP1.Host = "EX"
            SMTP1.Send(eMsg)

            att.Dispose()
        End If
        Return True
    Catch ex As Exception
        Return False
    End Try
End Function