LWJGL GLSL Subroutine not changing

Question

I'm having troubles with getting the subroutines in my shader to "switch" from Phong to Diffuse lighting but everything I've tried results in whichever function is first declared in my shader to always be called.

Here is my shader

#version 430
subroutine vec3 shadeModelType( vec4 position, vec3 normal);
subroutine uniform shadeModelType shadeModel;
layout (location = 0) in vec3 VertexPosition;
layout (location = 1) in vec3 VertexNormal;


out vec3 LightIntensity;
struct LightInfo {
vec4 Position; // Light position in eye coords.
vec3 La;       // Ambient light intensity
vec3 Ld;       // Diffuse light intensity
vec3 Ls;       // Specular light intensity
};
uniform LightInfo Light;

struct MaterialInfo {
vec3 Ka;            // Ambient reflectivity
vec3 Kd;            // Diffuse reflectivity
vec3 Ks;            // Specular reflectivity
float Shininess;    // Specular shininess factor
};
uniform MaterialInfo Material;

uniform mat4 viewMatrix;
uniform mat4 transformationMatrix;

uniform mat3 normalMatrix;
uniform mat4 ProjectionMatrix;


void getEyeSpace( out vec3 norm, out vec4 position )
{
norm = normalize(  mat3(transpose(inverse(viewMatrix *transformationMatrix))) *      

VertexNormal);

position = viewMatrix * transformationMatrix * vec4(VertexPosition,1.0);
}

subroutine( shadeModelType )
vec3 phongModel( vec4 position, vec3 norm )
{
vec3 s = normalize(vec3(Light.Position - position));
vec3 v = normalize(-position.xyz);
vec3 r = reflect( -s, norm );
vec3 ambient = Light.La * Material.Ka;
float sDotN = max( dot(s,norm), 0.0 );
vec3 diffuse = Light.Ld * Material.Kd * sDotN;
vec3 spec = vec3(0.0);
if( sDotN > 0.0 )
    spec = Light.Ls * Material.Ks *
           pow( max( dot(r,v), 0.0 ), Material.Shininess );

return ambient + diffuse + spec;
}

subroutine( shadeModelType )
vec3 diffuseOnly( vec4 position, vec3 norm )
{
    vec3 s = normalize( vec3(Light.Position - position) );
    return
    Light.Ld * Material.Kd * max( dot(s, norm), 0.0 );
}


void main()
{
    mat4 modelViewProject = ProjectionMatrix * viewMatrix *transformationMatrix ;
    mat4 normalMatrix = transpose(inverse(viewMatrix *transformationMatrix));

    vec3 eyeNorm;
    vec4 eyePosition;

    // Get the position and normal in eye space
    getEyeSpace(eyeNorm, eyePosition);

    // Evaluate the shading equation.  This will call one of
    // the functions: diffuseOnly or phongModel.
    LightIntensity = shadeModel( eyePosition, eyeNorm );

    gl_Position = modelViewProject * vec4(VertexPosition,1.0);
}

in my render method just before GLdrawelements I have

sub1 = GL40.glGetSubroutineIndex(programID, GL20.GL_VERTEX_SHADER, "diffuseOnly");
sub2 = GL40.glGetSubroutineIndex(programID, GL20.GL_VERTEX_SHADER, "phongModel");

produce a location of 0 and 1 respectively.

 int routineUniform = GL40.glGetSubroutineUniformLocation(programID,   
 GL20.GL_VERTEX_SHADER, "shadeModel");
 IntBuffer subroutineBuffer = BufferUtils.createIntBuffer(1).put(sub1 );
 System.out.println(routineUniform); //produces a 0;
 System.out.println(GL40.glGetProgramStagei(programID,   
 GL20.GL_VERTEX_SHADER, GL40.GL_ACTIVE_SUBROUTINE_UNIFORM_LOCATIONS));
 //prints 1;

 GL40.glUniformSubroutinesu(GL20.GL_VERTEX_SHADER, subroutineBuffer);

I've tried buffer utils.createIntBuffer(2) and put both in, I've created 2 seperate int buffers. I've actually completely removed the sub1 and sub2 locations and it defaults back to the first declared function.

Answer 1

It looks like you need to call flip() on the IntBuffer after the put() but before the call to glUniformSubroutinesu. Otherwise the buffer isn't rewound to the beginning and you're effectively sending nothing.