Minimizing the months required to decommission a wind farm In a FICO Mosel Xpress IVE model

Question

I am trying to find the most optimal way to decommission a wind farm, firstly based on minimising costs (which I've managed) and then by seeing what the minimum cost is with a limit to the months. Currently, I have 24 months, each with a cost associated and a maximum number of turbines that can be decommissioned that month.

I would like to set a variable limit to the months and re-run to see how much more it would cost to decommission.

I've tried setting Declarations for MAX months and months used and then setting the months used to be less than MAX months, but this doesn't work and I don't have many more ideas.

I feel like it somehow needs to try and finish the optimisations before for example, the 16th input in my arrays that declare the distances and the costs per month, but I'm not sure how to implement this.

My current declarations are as follows (but the bottom two are of no use currently):

DECLARATIONS
    
    MONTHS = 1..24
    PORTS = 1..5
     
    N1 = 75 
    N2 = 91 
    N3 = 88 
    N4 = 67 
    N5 = 90 
    
    M = 24
    
    CAPACITY: array(PORTS, MONTHS) of integer 
    COST: array(PORTS, MONTHS) of integer 
    
    DISTANCES1: array(MONTHS,PORTS) of real ! 2.d.p
    DISTANCES2: array(MONTHS,PORTS) of real ! 2.d.p
    DISTANCES3: array(MONTHS,PORTS) of real ! 2.d.p
    DISTANCES4: array(MONTHS,PORTS) of real ! 2.d.p
    DISTANCES5: array(MONTHS,PORTS) of real ! 2.d.p
    
    DECOM: array(MONTHS,PORTS) of mpvar
    DECOM1: array(MONTHS,PORTS) of mpvar ! decom of farm 1
    DECOM2: array(MONTHS,PORTS) of mpvar ! decom of farm 2
    DECOM3: array(MONTHS,PORTS) of mpvar ! decom of farm 3
    DECOM4: array(MONTHS,PORTS) of mpvar ! decom of farm 4
    DECOM5: array(MONTHS,PORTS) of mpvar ! decom of farm 5
    
    
    MAXMONTHS: array(MONTHS) of real
    
    MONTHSUSED: array(MONTHS) of mpvar 


    
END-DECLARATIONS

And the following constraints and objective:

MinCost := sum(m in MONTHS,  p in PORTS ) COST(p,m)*DECOM1(m,p)*DISTANCES1(m,p) +
 sum(m in MONTHS, p in PORTS) COST(p,m)*DECOM2(m,p)*DISTANCES2(m,p) +
 sum(m in MONTHS, p in PORTS) COST(p,m)*DECOM3(m,p)*DISTANCES3(m,p) +
 sum(m in MONTHS, p in PORTS) COST(p,m)*DECOM4(m,p)*DISTANCES4(m,p) +
 sum(m in MONTHS, p in PORTS) COST(p,m)*DECOM5(m,p)*DISTANCES5(m,p)

!constraints:

sum(m in MONTHS, p in PORTS) DECOM1(m,p) = N1
sum(m in MONTHS, p in PORTS) DECOM2(m,p) = N2
sum(m in MONTHS, p in PORTS) DECOM3(m,p) = N3
sum(m in MONTHS, p in PORTS) DECOM4(m,p) = N4
sum(m in MONTHS, p in PORTS) DECOM5(m,p) = N5

forall(m in MONTHS, p in PORTS) DECOM1(m,p) <= CAPACITY(p,m)
forall(m in MONTHS, p in PORTS) DECOM2(m,p) <= CAPACITY(p,m)
forall(m in MONTHS, p in PORTS) DECOM3(m,p) <= CAPACITY(p,m)
forall(m in MONTHS, p in PORTS) DECOM4(m,p) <= CAPACITY(p,m)
forall(m in MONTHS, p in PORTS) DECOM5(m,p) <= CAPACITY(p,m)



forall(m in MONTHS, p in PORTS) DECOM1(m,p) + DECOM2(m,p) + DECOM3(m,p) + DECOM4(m,p) + DECOM5(m,p) <= CAPACITY(p,m)

I've left out the data entries as they're large and likely unimportant

Any Help greatly appreciated.

Answer 1

If I understand the question correctly, you wish to reduce the number of months when the last decommission happens.

One way to achieve this would be to add a high penalty onto the cost for the last months.

Alternatively, a hard limit could be implemented via some additional constraints, for example using an array 'LASTMONTH':

 declarations
   LASTMONTH: array(MONTHS) of mpvar
 end-declarations

 forall(m in MONTHS) LASTMONTH(m) is_binary
 sum(m in MONTHS) LASTMONTH(m) = 1

 MAXM:=getlast(MONTHS)

 ! Logic constraint "if LASTMONTH(m)=1 then DECOM*(m2,p) = 0 for all m2>m"
 forall(m in MONTHS) 
   indicator(1, LASTMONTH(m), sum(m2 in (m+1)..MAXM) (DECOM1(m2,p) +
     DECOM2(m2,p) + DECOM3(m2,p) + DECOM4(m2,p) + DECOM5(m2,p)) <= 0)

With this, you could work with an objective function like this:

 minimize(sum(m in MONTHS) m*LASTMONTH(m))

or simply try and fix some earlier month, such as:

 LASTMONTH(m)=22

Note that with the latter, your problem might turn infeasible, so remember to check the problem status after the optimization run, before trying to report on a solution, for example using 'getprobstat':

 if getprobstat=XPRS_INF then
   writeln("Problem is infeasible")
   exit(1)
 end-if

With respect to the remark on indices: I agree, there really should be a third index set, I am calling it 'NRANGE' in this new version of your code snippet:

 declarations
  MONTHS = 1..24
  PORTS = 1..5
  NRANGE = 1..5
  N=[75,91,88,67,90]
  DISTANCES: array(MONTHS,PORTS,NRANGE) of real
  DECOM: array(MONTHS,PORTS,NRANGE) of mpvar
 end-declarations

 MinCost := sum(m in MONTHS, p in PORTS, n in NRANGE) 
   COST(p,m)*DECOM(m,p,n)*DISTANCES(m,p,n) 

 forall(n in NRANGE) sum(m in MONTHS, p in PORTS) DECOM(m,p,n) = N(n)

 forall(m in MONTHS, p in PORTS, n in NRANGE) DECOM(m,p,n) <= CAPACITY(p,m)

 forall(m in MONTHS, p in PORTS) sum(n in NRANGE) DECOM(m,p,n) <= CAPACITY(p,m)