Need to move lots of consistently named files to certain folders (Windows 7)

Question

I need to populate a bunch of folders with files of various types.

The destination folder structure is as follows

YEAR > COMMITTEE_NAME YEAR > YEAR MONTH COMMITTEE_NAME 

EX: 2015 > ADP 2015 > 2015 January ADP

The files to be moved are in folders by committee (MOM, ADP, etc.). I have to organize first by year, then by committee, then by month.

Each folder contains files of various types named by the date and committee (Ex: A Word Document from the ADP meeting of Jan 22, 2015 would be "012215ADP.doc").

I would like to somehow automate the populating of these folders as there are hundreds if not thousands of files to move.

My only programming experience is in MATLAB, which I am proficient in, but am not allowed to use due to corporate rules.

I know how to execute and modify .bat files, but do not know enough to make them.

Answer 1

@echo off
setlocal EnableDelayedExpansion

set "destination=C:\path\that\contain\destination\folders"

rem Change current folder to the one that contain the MOM, ADP, etc. folders
cd "C:\path\to\committees\folder"


rem Create the array of month names (i.e. month[01]=January, etc.)
set i=100
for %%a in (January February March April May June July August September October November December) do (
   set /A i+=1
   set "month[!i:~1!]=%%a"
)

rem Process all committee folders
for /D %%d in (*) do (

   rem Process all files in this folder
   cd "%%d"
   for %%f in (*.*) do (

      rem Format of file name is: "MMddYYCOM.ext"
      set "filename=%%~Nf"
      set "MM=!filename:~0,2!"
      set "YY=!filename:~4,2!"
      set "COM=!filename:~6,3!"

      rem Move this file to the proper destination folder
      for %%m in (!MM!) do set "dest="%destination%\20!YY!\!COM! 20!YY!\20!YY! !month[%%m]! !COM!"
      if not exist "!dest!" md "!dest!"
      move "%%f" "!dest!"

   )

   rem Go back to parent folder and pass to next committee folder
   cd ..

)