Newline and Linespace in PDF::API2

Question

Perl's PDF::API2 can put text on a page, like the following example does:

$pdf = PDF::API2->new();
$page = $pdf->page();
$page->mediabox('A4');    
$page->gfx->textlabel(50, 50, $pdf->corefont('Helvetica'), 10, "Hello world");
$pdf->saveas('test.pdf');

But I can not find any documentation for multi-line text, like the intuitive but not working string "Hello\nworld".

What is the proper symbol for a newline in the PDF?

Is there a method to increase/decrease line spacing?

Answer 1

Maybe module's POD is broken, look at the source. Then, e.g.

use strict;
use warnings;
use PDF::API2;

my $pdf  = PDF::API2->new();
my $page = $pdf->page();
$page->mediabox('A4');

my $content = $page->text();
$content->translate(50, 750);
$content->font($pdf->corefont('Helvetica'), 24);
$content->lead(30);
$content->section("What is the proper symbol for a newline in the PDF?\nIs there a method to increase/decrease line spacing?\n" x 5, 400, 500);
$pdf->saveas('test.pdf');

This example shows long line automatic wrapping, newline handling, and setting of leading (line spacing).

---

An update as to request in comment :). You can do it as Borodin suggested, calling 'standard' textlabel on your text split on newlines and updating text position manually, it's not difficult. But, TMTOWTDI, and you can use my quick (and dirty) solution below -- section is only used to handle newlines, auto-wrapping prevented with 'infinite' 'text-box'. My sub call semantics is similar to textlabel. Or you can add support for color, alignment, etc., and probably make it a proper method in your class.

use strict;
use warnings;
use PDF::API2;

my $s = <<'END';
What is the proper symbol for a newline in the PDF?
Is there a method to increase/decrease line spacing?
END

sub super_textlabel {
    my ($page, $x, $y, $font, $size, $text, $rotate, $lead) = @_;
    my $BIG = 1_000_000;
    $page->gfx()->save();
    my $txt = $page->text();
    $txt->font($font, $size);
    $txt->lead($lead);
    $txt->transform(-translate => [$x, $y], -rotate => $rotate);
    $txt->section($text, $BIG, $BIG);
    $page->gfx()->restore();
}

my $pdf  = PDF::API2->new();
my $page = $pdf->page();
$page->mediabox('A4');

super_textlabel($page, 50,  750, $pdf->corefont('Helvetica'), 12, $s, 0,  16);
super_textlabel($page, 200, 200, $pdf->corefont('Times'),     16, $s, 45, 24);
super_textlabel($page, 500, 400, $pdf->corefont('Courier'),   10, $s, 90, 50);

$pdf->saveas('test.pdf');

Answer 2

PDF has no concept of "lines". It will simply place text at the given start coordinates in the font and size you specify. It is up to you to calculate where the string must be split and what the coordinates of each subsequent line should be.

The PDF::API2::Content class does have distance, cr and nl methods, which simply move the pen to the previous start point plus the given offsets.