numbers go to the next empty cell?

Question

For some reason this script doesn't go to the next empty cell in column?  

What am I doing wrong ? I would love to be able to add today's date to next empty cell in column and would be great if those numbers will not not change but stay at that date

need some help thanks in advance.

on run {input, parameters}
 
 tell application "Numbers"
  activate
  tell the first table of the active sheet of document 1
   tell column "F"
    set r to (address of row of last cell whose value is greater than "")
    set r to r + 1
    set value of cell r to date string of (current date)
   end tell
  end tell
 end tell
 
 
 return input
end run

Answer 1

Here is code that I use to find the next empty cell in a column:

tell application "Numbers"
    tell front document
        tell table 1 of sheet 1
            set fullSheet to 1
            repeat
                set cellValue to value of cell ("A" & fullSheet) --of table 1 of sheet 1
                if cellValue = missing value then exit repeat
                set fullSheet to fullSheet + 1
            end repeat
        end tell
    end tell
end tell

I know it is not very glamorous, but it has continued to work through all of the Numbers upgrades since Feb 2014.

Answer 2

i'm not sure why the selector in your script doesn't work, but i needed to do the same thing and came up with this approach; i use error trapping to cover for the case where no rows are empty

tell application "Numbers"
  tell table 1 of active sheet of front document
    tell column "A"
      try
        set the_cell to first cell whose value is missing value
      on error -- no empty cell in this column, need to add row
        add row below last row
        set the_cell to cell (count of rows)
      end try
      set value of the_cell to current date
      
      -- get row number in case need to set values in other columns
      set the_row to address of row of the_cell
    end tell
  end tell
end tell