Open Screen Mirroring in Control Center for Sidecar?

Question

OS & Program Details

• macOS Monterey (12.3+): This is only applicable to 12.3 or above since the method of activating/deactivating Sidecar changed a bit with the introduction of Universal Control (rather than being in the CC Display module, the button for Sidecar got moved into Screen Mirroring)
• Device: M1 MacBook Pro 13-inch (Late 2020). Not sure if this matters, but thought it'd be helpful to include just in case.
• Application: Building and running in the built-in Script Editor.app

Problem

So going off of this link, I am trying to build an AppleScript that starts/ends a Sidecar connection, and achieving this through GUI scripting the Control Center (rather than System Preferences, or by including the Screen Mirroring menu bar item).

I seem to have part of it down, but am not able to actually click the Screen Mirroring button (or checkbox, as it's classified in AppleScript); it does nothing. Here's the code I have so far:

set deviceName to "iPad"
set sysVer to system version of (system info) as real


tell application "System Events"
    tell its application process "ControlCenter"
        activate
        
        -- Click the Control Center menu and give it time to draw
        click menu bar item "Control Center" of menu bar 1
        delay 1
        
        if sysVer ≥ 12.3 then
            -- Get the Screen Mirroring "checkbox" and click it
            set screenMirroringToggle to (checkbox 1 of window "Control Center" whose title is "Screen Mirroring")
            click screenMirroringToggle

            -- Do stuff that gets the iPad button to start/end Sidecar

        else
            -- Do stuff for other versions of macOS Monterey or Big Sur
        end if
    end tell
end tell

Things I've Tried

I am still a little new to AppleScript, so I tried building the script in iterations. I first tried getting all the possible checkboxes in the CC with this:

if sysVer ≥ 12.3 then
    -- Get all checkboxes in the Control Center menu
    set ccCheckboxes to title of (every checkbox of window "Control Center")
    return ccCheckboxes
end if

That returns this list (Link keyboard and mouse is not what I'm looking for — that is for Universal Control, not Sidecar):

{"Wi‑Fi", "Focus", "Bluetooth", "AirDrop", "Screen Mirroring", "Link keyboard and mouse", "Airplay Audio"}

Setting the Screen Mirroring checkbox throws no errors (and can be returned), but the click command doesn't (appear to) do anything with this:

set myToggle to (checkbox 1 of window "Control Center" whose title is "Screen Mirroring")
click myToggle

Just to make sure the click command actually does something, I tried it with the AirDrop checkbox via:

set myToggle to (checkbox 1 of window "Control Center" whose title is "AirDrop")
click myToggle

This works as expected; the AirDrop icon in the CC is toggled (switching between "Contacts Only" and "Off"). I then went ahead and tried it with every other checkbox returned in ccCheckboxes above, and everything but Screen Mirroring works: all toggles (Wi-Fi, Focus, Bluetooth, AirDrop) switch between on and off, and the rest (Link keyboard and mouse, Airplay Audio) open their secondary window. Am I doing something wrong or is this just a bug?

Edit: macOS Ventura (13.0+)

For anyone who stumbles upon this in the future.

Seems like GUI scripting is even more broken on this version than it was on Monterey. Most GUI items got their name moved from the title property to their description, so you'd have to do something like this:

set controlCenterMBI to (menu bar items of menu bar 1 whose description is "Control Center")

Alternatively, I'd recommend creating a workflow in Automator and use the Watch Me Do to record your clicks and import that as a Shortcut, then use the CLI command shortcuts run $SHORTCUT_NAME to run that Shortcut.

Answer 1

EDIT: Solution for Ventura 13.0.1

So it looks like it's harder to do on Ventura. As you said, the title is now in description, unfortunately I found that only to be true for "Control Center" itself on the menubar. All items within the Control Center dropdown window lacked a name, title, and description at least from what I could tell. So, it was basically trial and error until I found the correct object. Other things I noticed that differed from Monterey:

1. Screen Mirroring is now a button instead of a checkbox.
2. perform action 2 for the click event doesn't work now it's "action 1"

`

 tell application "System Events"

 tell its application process "ControlCenter"

    tell its menu bar 1
        -- click on and open Control Center drop down
        tell (UI elements whose description is "Control Center")
            click
        end tell
    end tell
    
    
    -- interact with Control Center window
    tell its window "Control Center"
        delay 0.5
        -- click screen mirroring button
        set screenMirroringButton to button 2 of group 1
        -- click screenMirroringButton click doesn't work
        perform action 1 of screenMirroringButton
    end tell
    
end tell
end tell

`

---

For Monterey

I found a solution that is working for me on 12.0.1, unfortunately I am locked in at this version and am unable to update to test on a newer version, so it may not work for you but worth a shot.

Just replace "click" with "perform action 2". It's weird but it works (on 12.0.1).

-- Get the Screen Mirroring "checkbox" and click it
    set screenMirroringToggle to (checkbox 1 of window "Control Center" whose title is "Screen Mirroring")
    perform action 2 of screenMirroringToggle

If you would like to see my applescript go here. I was able to select a device in the Screen Mirroring dropdown which also may help you with what you are wanting.

Answer 2

Solved: Starting Sidecar from iPad via a shortcut and „run script via ssh“

I have solved and Documented the problems and solutions! Should work on macOs Ventura & iPads wich support Apple Sidecar & the Shortcuts app.

Just get the script from my gitHub repo: github.com/ManuelTDev/SideCar_via_ssh

Documentation is also attached as a readme file!