PDDL Predicate name must be a string

Question

I am trying to solve a planning assignment with pddl and i wrote the following domain

 (define (domain Monster)
    (:requirements :strips)
    (:predicates (player ?p) (location ?x) (monster ?m) (treasure ?tr) (trap ?tp) (weapon ?w) (flyer ?f) ;entities 
             (playerat ?player ?location) (monsterat ?monster ?location) (trapat ?trap ?location) (treasureat ?trasure ?location) (weaponat ?weapon ?location) (flyerat ?flyer ?location); relations 
             (gameOver ?p) (holdsw ?p) (holdsf ?p) (holdst ?p) (go ?A ?B) (close ?A ?B)
    )

    (:action Move  ;Move from location A to location B
        :parameters (?P ?A ?B ?M) ; P->Player A->Location_1 B->Location_2  
        :precondition (and(player ?P) (location ?A) (location ?B) (monster ?M) (playerat ?P ?A) (go ?A ?B) (not(monsterat ?M ?B)) )
        :effect (and(playerat ?P ?B) (not(playerat ?P ?A)) )
    )

    (:action PickWeapon ; picking up weapon
        :parameters (?P ?L ?W) ;P->player L->location W->Weapon
        :precondition (and(player ?P) (location ?L) (weapon ?W) (playerat ?P ?L) (weaponat ?W ?L)  )
        :effect (and(holdsw ?P) (not(weaponat ?W ?L)))
    )
    
    (:action PickFlyer ;picking up flyer
        :parameters (?P ?L ?F) ;P->player L->location F->flyer 
        :precondition (and(player ?P) (location ?L) (flyer ?F) (playerat ?P ?L) (flyerat ?F ?L)   )
        :effect (and(holdsf ?P) (not(flyerat ?F ?L)) )
    )
    
    (:action PickTreasure ;picking up treasure
        :parameters (?P ?L ?T) ;P->player L->location T->treasure
        :precondition (and(player ?P) (location ?L) (treasure ?T) (playerat ?P ?L) (treasureat ?T ?L)   )
        :effect (and(holdst ?P) (not(treasureat ?T ?L)) )
    )
    
    (:action PlayerKilled ;player killed
        :parameters (?P ?L ?M) ;P->player L->location M->monster
        :precondition (and(player ?P) (location ?L) (monster ?M) (playerat ?P ?L) (monsterat ?M ?L) (not(holdsw ?P)) (not(holdsf ?P)) )
        :effect (and(gameOver ?P) (not(playerat ?P ?L)) ); Game Over
    )
    
    (:action PlayerTraped ;Player traped 
        :parameters (?P ?L ?TR) ;P->player L->location TR->trap
        :precondition (and(player ?P) (location ?L) (trap ?TR) (playerat ?P ?L) (trapat ?TR ?L) (not(holdsf ?P)) )
        :effect (and(gameOver ?P) (not(playerat ?P ?L)) )
    )
    
    (:action Kill ;Killing Monster
        :parameters (?P ?A ?M ?B) ;P->player L->location M->monster 
        :precondition (and(player ?P) (location ?B) (location ?A) (monster ?M) (playerat ?P ?A) (monsterat ?M ?B) (holdsw ?P) (close ?A ?B) (go ?A ?B) )
        :effect (and(playerat ?P ?B) (not(monsterat ?M ?B)) (not(holdsw ?P)) )
    )

    (:action FlyOverMonster
        :parameters (?P ?F ?L ?A ?M) ;P->player L->location F->flyer M->monster
        :precondition (and(player ?P) (location ?L) (location ?A) (monster ?M) (playerat ?P ?A) (monsterat ?M ?L) (holdsf ?P) (close ?A ?L) (go ?A ?L) )
        :effect (and(playerat ?P ?L) (not(holdsf ?P)) )
    )
    
    (:action FlyOverTrap
        :parameters (?P ?F ?L ?A ?TR) ;P->player L->location F->flyer TR->trap
        :precondition (and(player ?P) (location ?L) (location ?A) (trap ?TR) (playerat ?P ?A) (trapat ?TR ?L) (holdsf ?P) (close ?A ?L) (go ?A ?L) )
        :effect (and(playerat ?P ?L) (not(holdsf ?P)) )
    )
    
)

problem i defined the problem to be planned as follows

(define (problem Monster2)
(:domain Monster)

(:objects a b c d e f g h i pl mo tp fl tr wp
)

(:init
    (location a) (location b) (location c) (location d) (location e) (location f) (location g) (location h) (location i)
    (player pl) (monster mo) (trap tp) (flyer fl) (treasure tr) (weapon wp)
    (go a b) (go b a) (go b c) (go c b) (go c d) (go d c) (go a e) (go e b) (go e f) (go f d) (go e g) (go e h) (go h e) (go h i) (go i h)
    (close b c) (close c d) (close e f)
    (playerat pl a) (monsterat mo c) (treasureat tr d) (trapat tp f) (weaponat wp h) (flyerat fl i)
)

(:goal (and
            (holdst pl)
            (playerat pl a)
        )
)

)

Trying to solve the problem i Changed my code but now I am facing another problem. The agent after killing the monster does not go to the next room but he returns back and then jambs to d room collects the treasure and stay at d. The strange thing is that the planer says that the agent is now at room c and in next state it says he is at room b.

Planner result
Planer Kill Monster agent at room c

Planner result Planner Move next supposed to be room d and it says room b state which is wrong

Answer 1

Actually there are several mistakes in the PDDL file. I tested it with FF.

In the domain file you missed some AND and few parenthesis in different action definitions, e.g.

(:action Kill
    :parameters (?P ?L ?M ?A) ;P->player L->location M->monster
    :precondition (and(player ?P) (location ?L) (location ?A) (monster ?M) (atp ?P ?A) (atm ?M ?L) (holdsw ?P ?W) (close ?A ?L) )
    :effect (and (not(atm ?M ?L)) (not(holdsw ?P ?W)) (atp ?P ?L))
)

Then you forgot to declare some predicates used in domain definition, e.g. at1...at6, located

Then in actions FlyOverMonster and FlyOverTrap you forgot to declare variable ?A, variable ?W in actions Kill and PlayerKilled.

In action PlayerKilled you have a predicate hold that doesn't appear anywhere else.

I don't continue, but I hope that the corrections are clear. Then, the planner should point out the kind of error it encounters.

Answer 2

Check your predicates name, I am not sure numbers are supported in their names, and in their parameter names. In your problem, I can see occurrences of at1, at2, etc... These predicates are named strangely, and I am suspicious it is meant to work. Moreover, they are not declared in your domain.