perl datetime add months fails in dst timezone

Question

This two lines are the test data

 my $dt = DateTime->new( {
     year => 2014, month => 9, day => 19, 
     hour => 00, minute=> 00, second=> 00});
 $dt->set_time_zone(DateTime::TimeZone->new( name => 'America/Sao_Paulo' ));

Now I want to add one month with the date which fails

 $dt->add ( months => 1 );
 # This  fails because  the result date is 2014-10-19 00:00:00 and for Sao_Paulo
 # the result should be a DST shifted time 2014-10-19 01:00:00 

The simplest solution I have come up with is this

 my $tz_backup = $dt->time_zone();   # Backup the timezone
 $dt->set_time_zone('UTC');          # Moving the time to UTC to get rid of DST complexities
 $dt->add ( months => 1 );           # Perform the original operation
 $dt->set_time_zone($tz_backup);     # Setting back the original timezone

Question is, could there by any flaw in this solution?

If this approach is really correct for all timezone and all DST scenarios, then why perl DateTime library doesnt do this itself? Answer of this question is not necessary if my solution is correct ;)

Thanks

Answer 1

Your solution is recommended in the documentation, so it should be OK.

Also, when I ran your original code, I got an error back:

Invalid local time for date in time zone: America/Sao_Paulo

Answer 2

Why doesn't the library do it itself? Because a month is not a certain number of seconds, it is a certain (varying by month) number of days. If what you wanted was to add a month's worth of seconds, you can do:

my $dt = DateTime->new( year => 2014, month => 9, day => 19, time_zone => 'America/Sao_Paulo' );
$dt->add( seconds => DateTime->last_day_of_month( year => $dt->year, month => $dt->month )->day * 24 * 60 * 60 );

Or just use UTC, as you suggest.

Answer 3

If this approach is really correct for all timezone and all DST scenarios

The correct approach to do what?

Get the date-time one month later? No, that gives the wrong result.

To do date arithmetic using DateTime? I'd use "floating" instead of "UTC", which saves you from having to convert back. Working with UTC can also give you the wrong result.

$ perl -MDateTime -E'
   my $dt = DateTime->now( time_zone => "America/Toronto" )->set_hour(0);
   say $dt->ymd;

   say $dt->clone
      ->set_time_zone("UTC")
         ->truncate( to => "day" )
            ->set_time_zone("America/Toronto")
               ->ymd;

   say $dt->clone
      ->set_time_zone("floating")
         ->truncate( to => "day" )
            ->ymd;
'
2014-11-20
2014-11-19   # XXX
2014-11-20   

then why perl DateTime library doesnt do this itself?

You asked it to give the DT one month later. It would be incorrect to give one month and one hour later without being told to.

In other words, people expect addition to function as follows:

timestamp + duration - duration = timestamp