perl datetime truncate fails when falling into a DST time shift

Question

use DateTime;
use DateTime::TimeZone;

my $dt = DateTime->new( {
               year => 2014, month => 10,  day => 19, 
               hour => 2,  minute=> 2,  second=> 0
});
$dt->set_time_zone(DateTime::TimeZone->new( name => 'America/Sao_Paulo' ));
$dt->truncate(to => 'day');

is failing with a message Invalid local time for date in time zone: America/Sao_Paulo.

Because 2014-10-19 00:00:00 is not a valid time in America/Sao_Paulo timezone. The end result should be 2014-10-19 01:00:00.

My theory in pseudocode

Try to truncate directly to the datetime object inside an eval

IF fails
   IF the truncation level is "day"
      -1 day 
      truncate
      + seconds of a day
   IF the truncation level is "month"
      -1 month 
      truncate
      seconds of a month. <--- Now here I need to take care of seconds of every month and even leapyear
 ELSE im happy

Any help to improve my theory or provide a much simpler approach?

Answer 1

Since the error occurs only when the hour is being set to zero, the correction must always be to set the hour to one instead. Zones where the hour changes other than at midnight won't have the problem.

That means you can write a trivial exception handler like this.

I'm tempted to say that no zone starts daylight saving on the first day of a month, so the problem shouldn't occur when truncating to the month. But I can't guarantee that, so I've coded a block for that as well.

use strict;
use warnings;
use 5.010;

use DateTime;
use DateTime::TimeZone;
use Try::Tiny;

my $dt = DateTime->new( {
    year => 2014, month => 10,  day => 19, 
    hour => 2,  minute=> 2,  second=> 0
});

my $sao_paolo = DateTime::TimeZone->new( name => 'America/Sao_Paulo' );

$dt->set_time_zone($sao_paolo);

try {
  $dt->truncate(to => 'day');
}
catch {
  die $_ unless /Invalid local time for date/;
  $dt->truncate(to => 'hour');
  $dt->set({hour => 1});
};

say $dt;

try {
  $dt->truncate(to => 'month');
}
catch {
  die $_ unless /Invalid local time for date/;
  $dt->truncate(to => 'hour');
  $dt->set({day => 1, hour => 1});
};

say $dt;

output

2014-10-19T01:00:00
2014-10-01T00:00:00