Perl DBI array - split

Question

I'm trying to split the results of a mysql query using perl and DBI module. Here's my code:

#!/usr/bin/perl -w
use DBI;

$dbh = DBI->connect('DBI:mysql:host', 'user', 'password'
                   ) || die "Could not connect to database: $DBI::errstr";


$sql = "SELECT * FROM users;";
$sth = $dbh->prepare($sql);
$sth->execute or die "SQL Error: $DBI::errstr\n";
while (@row = $sth->fetchrow_array) {

my @value1 = split(".",@row);
my $domain = $value1[1];

print "$domain\n";

}

$dbh->disconnect();

The query result is similar to: username.domain So I want to split the result with "." to show only the "domain" but it return me an error: Use of uninitialized value $domain in concatenation (.) or string ...

Thanks!

Answer 1

#!/usr/bin/perl -w
use strict;
use warnings;
use DBI;


my $dbh = '';
my $sql = '';
my $sth = '';
my @dbRow= ();


$dbh = DBI->connect('DBI:mysql:host', 'user', 'password'
                   ) || die "Could not connect to database: $DBI::errstr";


$sql = "SELECT * FROM users;";
$sth = $dbh->prepare($sql);
$sth->execute or die "SQL Error: $DBI::errstr\n";
while (@dbRow = $sth->fetchrow_array) {
    foreach my $dbData (@dbRow)
    {
        print split (/\./,$dbData)->[1]; 
    }
}

$dbh->disconnect();

Answer 2

Let's walk through your code. With added comments.

#!/usr/bin/perl -w
# Always always, start Perl programs with "use strict" and "use warnings".
# I know you have "-w" on the shebang line, but lose that as "use warnings"
# is a more flexible improvement.

use DBI;

# If you "use strict" then you need to declare all of your variables. So
# this line should start "my $dbh = ".
$dbh = DBI->connect('DBI:mysql:host', 'user', 'password'
                   ) || die "Could not connect to database: $DBI::errstr";


$sql = "SELECT * FROM users;";
$sth = $dbh->prepare($sql);
$sth->execute or die "SQL Error: $DBI::errstr\n";
while (@row = $sth->fetchrow_array) {
    # Code is always easier to follow with good indentation.

    # Several issues here.
    # The first parameter to split() is a regular expression. I recommend
    # always putting it in /.../ so you're not tempted to assume it's a string.
    # In a regex, the dot has a special meaning. It matches any character. To
    # match a literal dot, you need to escape it with a \.
    # The second parameter to split() is a string to split. You can't give it
    # an array (well, you can, but it will use the number of elements in the 
    # array which is probably not what you want!
    my @value1 = split(".",@row);
    my $domain = $value1[1];

    print "$domain\n";

}

$dbh->disconnect();

Taking all of those, your code should probably look more like this:

#!/usr/bin/perl

use strict;
use warnings;
use DBI;

my $dbh = DBI->connect('DBI:mysql:host', 'user', 'password')
    || die "Could not connect to database: $DBI::errstr";

my $sql = "SELECT * FROM users;";
my $sth = $dbh->prepare($sql);
$sth->execute or die "SQL Error: $DBI::errstr\n";

while (my @row = $sth->fetchrow_array) {    
    # Assume $row[0] is the value to want to split
    my @value1 = split(/\./, $row[0]);
    my $domain = $value1[1];

    print "$domain\n";
}

$dbh->disconnect();