Plotting own function in scilab

Question

Hey i have an issuse with plotting my own function in scilab. I want to plot the following function

function f =  test(n)
if n < 0 then
    f(n) = 0;
elseif n <= 1 & n >= 0   then
    f(n) = sin((%pi * n)/2);
else
    f(n) = 1;
end  
endfunction

followed by the the console command

x = [-2:0.1:2];
plot(x, test(x));

i loaded the function and get the following error

!--error 21 Invalid Index. at line 7 of function lala called by :
plot(x, test(x))

Can you please tell me how i can fix this

Answer 1

So i now did it with a for loop. I don't think it is the best solution but i can't get the other ones running atm...

function f =  test(n)

   f = zeros(size(n));

   t = length(n);
   for i = 1:t
       if n(i) < 0 then
          f(i) = 0;
       elseif n(i) <= 1 & n(i) >= 0
          f(i) = sin((%pi * n(i)/2));
       elseif n(i) > 1 then
          f(i) = 1;
       end
   end

endfunction

I guess i need to find a source about this issue and get used with the features and perks matlab/scilab have to over :) Thanks for the help tho

Answer 2

The original sin is

function f =  test(n)
   (...)
   f(n) = (...)
   (...)
endfunction

f is supposed to be the result of the function. Therefore, f(n) is not "the value that the function test takes on argument n", but "the n-th element of f". Scilab then handles this however it can; on your test case, it tries to access a non-integer index, which results in an error. Your loop solution solves the problem.

Replacing all three f(n) by f in your first formulation makes it into something that works... as long as the argument is a scalar (not an array).

If you want test to be able to accept vector arguments without making a loop, the problem is that n < 0 is a vector of the same size as n. My solution would use logical arrays for indexing each of the three conditions:

function f =  test(n)

   f = zeros(size(n));
   negative = (n<0);//parentheses are optional, but I like them for readability
   greater_than_1 = (n>1);
   others = ~negative & ~greater_than_1;

   f(isnegative)=0;
   f(greater_than_1)=1;
   f(others) = sin(%pi/2*n(others));

endfunction