Powerapps - Unable to get child gallery items

Question

I have parent & child blank vertical Gallery and for parent DataSource is GroupBy(jsonData,"group_id","DATA") here i have two groups. for child Gallery DataSource is ThisItem.DATA, in child gallery there are 5 text input fields, after clicking Submit button i am unable to get text input fields data from child Gallery. I have tried below methods but ChildGal items count is always 0 only
ForAll(ParentGal.AllItems,Notify(ThisItem.ChildGal.AllItemsCount,Success,3000)),
Notify(ChildGal.AllItemsCount,Success,3000))

Answer 1

Currently we cannot access the AllItems property of a nested gallery from outside the outer gallery. One way to work around this limitation is to collect the data on the outer gallery (such as in a hidden label), and then this value can be accessed from outside.

For example, if I have this dataset:

ClearCollect( CityPopulations,
    { City: "London",    Country: "United Kingdom", Population: 8615000},
    { City: "Berlin",    Country: "Germany",        Population: 3562000},
    { City: "Madrid",    Country: "Spain",          Population: 3165000},
    { City: "Rome",      Country: "Italy",          Population: 2874000},
    { City: "Paris",     Country: "France",         Population: 2273000},
    { City: "Hamburg",   Country: "Germany",        Population: 1760000},
    { City: "Barcelona", Country: "Spain",          Population: 1602000},
    { City: "Munich",    Country: "Germany",        Population: 1494000},
    { City: "Milan",     Country: "Italy",          Population: 1344000}
)

And my (outer) gallery Items property is set to GroupBy( CityPopulations, "Country", "Cities" ), and I have the name and population of the cities in a nested gallery:

I can add a (hidden) label to the outer gallery with the following expression for its Text property:

Concat(Gallery2.AllItems, $"{City}${TextInput1.Text}", "|")

This will merge all properties of the nested gallery using the separators | (for each row) and $ (for the properties I'm interested in).

From outside the galleries, I can then reference that property

Clear(myCollection);
ForAll(
    Gallery1.AllItems,
    ForAll(
        Split(ThisRecord.lblAllTextInputs.Text, "|"),
        With(
            { parts:Split(Value, "$") }, 
            Collect(
                myCollection,
                {
                    City: Index(parts, 1).Value,
                    NewPopulation: Value(Index(parts, 2).Value)
                }
            )
        )
    )
)

Hope this helps!