Process WaitForSingleObject - responsive UI

Question

I am using the following code for understanding how to wait for a Process to end while it's active.
In my code, just when notepad opens, I see the MessageBox.

How do I wait until Notepad is closed, without making my Form unresponsive?

Public Class Form1
    Private Const WAIT_INFINITE = -1&
    Private Const SYNCHRONIZE = &H100000

    Private Declare Function OpenProcess Lib "kernel32" _
  (ByVal dwDesiredAccess As Long,
   ByVal bInheritHandle As Long,
   ByVal dwProcessId As Long) As Long

    Private Declare Function WaitForSingleObject Lib "kernel32" _
  (ByVal hHandle As Long,
   ByVal dwMilliseconds As Long) As Long

    Private Declare Function CloseHandle Lib "kernel32" _
  (ByVal hObject As Long) As Long

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim hProcess As Long
        Dim taskId As Long
        Dim cmdline As String

        cmdline = "notepad.exe"
        taskId = Shell(cmdline, vbNormalFocus)

        hProcess = OpenProcess(SYNCHRONIZE, True, taskId)
        Call WaitForSingleObject(hProcess, WAIT_INFINITE)
        CloseHandle(hProcess)

        MsgBox ("The shelled app has ended.")
    End Sub
End Class

Answer 1

At its simplest, a WaitForExitAsync would look like:

Private Async Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    Dim p = Process.Start("notepad.exe")
    Await p.WaitForExitAsync()
    MsgBox ("The shelled app has ended.")
End Sub

Answer 2

In .Net Framework / .Net Core, you can use the asynchronous, event-driven, version of WaitForExit, subscribing to the Exited event, which is raised when the Process you started terminates.

Note: The event is raised in ThreadPool Threads. You can set the Process.SynchronizingObject to the current Form instance to marshal the events to the UI Thread.

In .Net Framework, set [Process].StartInfo.UseShellExecute to False, since the default is True.
In .Net Core the default is already False.

When the event is raised, the Process has already exited (HasExited is True), so not all the usual information is available. The Process.StartInfo (the ProcessStartInfo object) is accessible, plus of course the ExitTime and other values (inspect the Process object when the event is raised).

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    Dim p = New Process()
    p.StartInfo.FileName = "notepad.exe"
    p.StartInfo.UseShellExecute = False
    p.SynchronizingObject = Me
    p.EnableRaisingEvents = True
    AddHandler p.Exited,
        Sub()
            Dim processName = p.StartInfo.FileName
            Dim exitTime = p.ExitTime
            p?.Dispose()
            MessageBox.Show("Process exited")
            DoSomethingElseRelated(processName, exitTime)
        End Sub
    p.Start()
End Sub