Read ini files without section names

Question

I want to make a configuration file which hold some objects, like this (where of course none of the paramaters can be considered as a primary key)

param1=abc
param2=ghj

param1=bcd
param2=hjk
; always the sames parameters

This file could be read, lets say with Config::IniFiles, because it has a direct transcription into ini file, like this

[0]
param1=abc
param2=ghj

[1]
param1=bcd
param2=hjk

with, for example, something like

perl -pe 'if (m/^\s*$/ || !$section ) print "[", ($section++ || 0) , "]"'

And finish with

open my $fh, '<', "/path/to/config_file.ini" or die $!;
$cfg = Config::IniFiles->new( -file => $fh );
(...parse here the sections starting with 0.)

But, I here ask me some question about the thing becoming quite complex....

(A) Is There a way to transform the $fh, so that it is not required to execute the perl one-liner BEFORE reading the file sequentially? So, to transform the file during perl is actually reading it.

or

(B) Is there a module to read my wonderfull flat database? Or something approching? I let myslef said, that Gnu coreutils does this kind of flat file reading, but I cannot remember how.

Answer 1

You can create a simple subclass of Config::INI::Reader:

package MyReader;

use strict;
use warnings;

use base 'Config::INI::Reader';

sub new {
    my $class = shift;
    my $self = $class->SUPER::new( @_ );

    $self->{section} = 0;

    return $self;
}


sub starting_section { 0 };

sub can_ignore { 0 };

sub parse_section_header {
     my ( $self, $line ) = @_;

    return $line =~ /^\s*$/ ? ++$self->{section} : undef ;
}

1;

With your input this gives:

% perl -MMyReader -MData::Dumper -e 'print Dumper( MyReader->read_file("cfg") )'
$VAR1 = {
          '1' => {
                   'param2' => 'hjk',
                   'param1' => 'bcd'
                 },
          '0' => {
                   'param2' => 'ghj',
                   'param1' => 'abc'
                 }
        };

Answer 2

You can store the modified data in a real file or a string variable, but I suggest that you use paragraph mode by setting the input record separator $/ to the empty string. Like this

use strict;
use warnings;

{
  local $/ = '';  # Read file in "paragraphs"
  my $section = 0;
  while (<DATA>) {
    printf "[%d]\n", $section++;
    print;
  }
}

__DATA__
param1=abc
param2=ghj

param1=bcd
param2=hjk

output

[0]
param1=abc
param2=ghj

[1]
param1=bcd
param2=hjk

---

Update

If you read the file into a string, adding section identifiers as above, then you can read the result directly into a Config::IniFiles object using a string reference, for instance

my $config = Config::IniFiles->new(-file => \$modified_contents)

This example shows the tie interface, which results in a Perl hash that contains the configuration information. I have used Data::Dump only to show the structure of the resultant hash.

use strict;
use warnings;

use Config::IniFiles;

my $config;
{
  open my $fh, '<', 'config_file.ini' or die "Couldn't open config file: $!";
  my $section = 0;
  local $/ = '';
  while (<$fh>) {
    $config .= sprintf "[%d]\n", $section++;
    $config .= $_;
  }
};

tie my %config, 'Config::IniFiles', -file => \$config;

use Data::Dump;
dd \%config;

output

{
  # tied Config::IniFiles
  "0" => {
           # tied Config::IniFiles::_section
           param1 => "abc",
           param2 => "ghj",
         },
  "1" => {
           # tied Config::IniFiles::_section
           param1 => "bcd",
           param2 => "hjk",
         },
}

Answer 3

You may want to perform operations on a flux of objects (as Powershell) instead of a flux of text, so

use strict; 
use warnings; 
use English;

sub operation {
    # do something with objects
    ...
}

{
local $INPUT_RECORD_SEPARATOR = '';
# object are separated with empty lines
while (<STDIN>) {
    #                  key       value
    my %object = ( m/^ ([^=]+) = ([[:print:]]*) $ /xmsg ); 
    # key cannot have = included, which is the delimiter
    # value are printable characters (one line only) 
    operation ( \%object )  
} 

A like also other answers.

Answer 4

You can use a variable reference instead of a file name to create a filehandle that reads from it:

use strict;
use warnings;
use autodie;

my $config = "/path/to/config_file.ini";

my $content = do {
  local $/;
  open my $fh, "<", $config;
  "\n". <$fh>;
};

# one liner replacement
my $section = 0;
$content =~ s/^\s*$/ "\n[". $section++ ."]" /mge;

open my $fh, '<', \$content;
my $cfg = Config::IniFiles->new( -file => $fh );
# ...