replacing only combination symbols dot + newline

Question

How to correct replace only combination dot and newline (.\n) with sed or tr

tr -d '.\n' remove all finded dots and newlines, but i need remove/replace only combinations

sed 's/\.\n//g' - dont replace anything

Many thanks

Answer 1

This might work for you (GNU sed):

sed ':a;N;s/\.\n//;ta;P;D' file

Append another line to the current line and test for the required match. If a match is found repeat otherwise print the first line and repeat.

EDIT:

Sed commands are separated by ;'s:

• :a names a label a
• N append a newline and the next line to the current line in the pattern space (PS). If there are no further lines, print the current PS.
• s/\.\n// is a substitution command that matches a . and a newline and replaces them with nothing.
• ta if the previous substitution was successful, jump to the label a and reset the internal flag marking a successful substitution.
• P print upto and including the first newline in the PS. If there are no newlines just print the PS.
• D delete upto and including the first newline in the PS. If PS is not empty resume at the first sed command (do not replenish the PS with the next line), otherwise begin the sed cycle again,

Answer 2

You can use gnu sed like this:

s='Hello Mr. Foo.
 - How are you?
Life is good.'

sed -E '/\.$/{:a;N;s/\.\n//;ta}' <<< "$s"

Hello Mr. Foo - How are you?
Life is good.

Other option is to use awk:

awk -v RS= '{gsub(/\.\n/, "")} 1' <<< "$s"

Hello Mr. Foo - How are you?
Life is good.

Answer 3

Perl to the rescue:

perl -pe 's/\.\n//' < file.old > file.new

Answer 4

With GNU sed:

sed -z 's/\.\n//g' file