Replacing Tomcat with Undertow in Vaadin + Spring boot project - ERR_CONNECTION_CLOSED

Question

I want to replace Tomcat with undertow. Everything seems fine but there is no error and any other information that something is wrong when I try to conenct to rest api or vaadin views. Only browser gives error: "ERR_CONNECTION_CLOSED"

build.gradle contents:

configurations.all {
    exclude group: 'org.springframework.boot', module:'spring-boot-starter-tomcat'
}


dependencies {
    implementation "com.vaadin:vaadin-core:$vaadinVersion"
    implementation "org.springframework.boot:spring-boot-starter-security:$springBootVersion"
    implementation("org.springframework.boot:spring-boot-starter-web:$springBootVersion") {
        exclude group: 'com.fasterxml.jackson.core'
        exclude group: 'com.fasterxml.jackson.datatype'
        exclude group: 'com.fasterxml.jackson.module'
        exclude group: 'org.springframework.boot', module: 'spring-boot-starter-tomcat'
        exclude module: 'spring-boot-starter-tomcat'
        exclude group: 'org.apache.tomcat.embed'
    }

    implementation("org.springframework.boot:spring-boot-starter-undertow:$springBootVersion")


    implementation ("org.springframework.boot:spring-boot-starter-parent:$springBootVersion") {
//        exclude module: 'spring-boot-starter-tomcat'
    }
    implementation "org.springframework.boot:spring-boot-starter-mail:$springBootVersion"
    implementation "org.springframework.boot:spring-boot-configuration-processor:$springBootVersion"
    implementation("com.vaadin:vaadin-spring-boot-starter:$vaadinVersion")
    implementation ("com.vaadin:vaadin-spring-boot-starter:$vaadinVersion")


    implementation ("com.vaadin:vaadin-bom:${vaadinVersion}") {
        exclude group: 'org.springframework.boot', module:'spring-boot-starter-tomcat'
    }

    implementation 'com.google.code.gson:gson:2.10.1'

    implementation "org.springframework.boot:spring-boot-starter-data-jpa:$springBootVersion"
   

}

There are no errors or any other information in console. Cant access vaadin views and rest api. When I switch back to tomcat - everything works fine. How can I fix this ? I really need to replace tomcat with undertow.

Answer 1

I downloaded a new project from https://start.vaadin.com and changed the build.gradle as below.

Update

I also had to exclude tomcat on the Vaadin dependency.

buildscript {
    repositories {
        mavenCentral()
        maven { setUrl("https://maven.vaadin.com/vaadin-prereleases") }
        }
}
plugins {
    id 'org.springframework.boot' version '3.1.5'
    id 'io.spring.dependency-management' version '1.0.15.RELEASE'
    id 'java'
    id 'com.vaadin'
}

repositories {
    mavenCentral()
    maven { setUrl("https://maven.vaadin.com/vaadin-prereleases") }
    maven { setUrl("https://maven.vaadin.com/vaadin-addons") }
}

configurations {
    developmentOnly
    runtimeClasspath {
        extendsFrom developmentOnly
    }
}

dependencies {
    implementation('com.vaadin:vaadin-spring-boot-starter') {
        exclude group: 'org.springframework.boot', module: 'spring-boot-starter-tomcat'
    }
    implementation('org.springframework.boot:spring-boot-starter-web') {
        exclude group: 'org.springframework.boot', module: 'spring-boot-starter-tomcat'
    }
    implementation('org.springframework.boot:spring-boot-starter-undertow')
    developmentOnly 'org.springframework.boot:spring-boot-devtools'
    testImplementation('org.springframework.boot:spring-boot-starter-test') {
        exclude group: 'org.junit.vintage', module: 'junit-vintage-engine'
    }
}

dependencyManagement {
    imports {
        mavenBom "com.vaadin:vaadin-bom:$vaadinVersion"
    }
}