SELECT TYPE with unlimited polymorphic pointer to CHARACTER(*) variable

Question

Following example uses Fortran 2003 features for defining unlimited polymorphic pointers and performing actions based on the variable type following a select type construct. The subroutine handleP prints the value of the argument in dependence of it's type.

program example
    implicit none
    type name
        character(22) :: n
    end type

    character(len=7) :: mystring
    mystring = 'Initial'

    call handleP(mystring)
    call handleP('Initial')
    call handleP(name('Initial'))

    contains

        subroutine handleP(p)
            class(*), intent(in) :: p

            select type(p)
            type is (character(len=*))
                write(*,*) len(p), ': ', p
            class is (name)
                write(*,*) len(p%n), ': ', p%n
            class default
                write(*,*) 'Unknown type'
            end select
        end subroutine

end program example

Compiling with gfortran version 4.8 gives following output:

       7 : Initial
       0 :
      22 : Initial

So, with call handleP(mystring) everything works as expected, but with call handleP('Initial') the printing fails. Calling with a type(name) argument also works.

Is the behaviour with call handleP('Initial') a gfortran bug or am I doing something wrong? If it is a bug, what could I do to prevent it?

Answer 1

I just want to let everyone know that the issue is fixed under gFortran 4.9.3-1 which comes with current MinGW installation.

Answer 2

This is probably what you want:

program example
    implicit none
    type name1
        character(22) :: n
    end type

    character(len=7) :: mystring
    mystring = 'Initial'

    call handleP(mystring)
    call handleP('Initial')
    call handleP(name1('Initial'))

    contains

        subroutine handleP(p)
            class(*), intent(in) :: p

            select type(p)
            type is (character(len=*))
                write(*,*) len(p), ': ', p
            class is (name1)
                write(*,*) len(trim(adjustl(p%n))), ': ', p%n
            class default
                write(*,*) 'Unknown type'
            end select
        end subroutine

end program example

The second call doesn't work since 'Initial' is not a variable. The 22 before was just the length which you defined in the type declaration. So I adjusted the length of it.