Show sort ordinal numbers as count in a list

Question

I have the following input file

system info com1 command set
system info com2 command set 
system command set1 information description test
system command 21-22 information description pass
system command T1-T2-T3 information description file
system command commonset information description info

and the following command

awk '/system command/&&/information description/ { gsub("\"","") ; print ++ OFS") Command = " $3}' inputfile.txt

gives me the following output

1) Command = set1
2) Command = 21-22
3) Command = T1-T2-T3
4) Command = commonset

Is there a way that my commands list count is not with simple numbers but with sort ordinal numbers and to have an output like this

1st) Command = set1
2nd) Command = 21-22
3rd) Command = T1-T2-T3
4th) Command = commonset

Answer 1

There is no built function to get that ordinal. We need to get our hands dirty and write this code:

awk 'function ordinal(i,   mod, str) {mod = i%10; str=i; if (i~/1[1-3]$/) str=str "th"; else if (mod==1) str=str "st"; else if (mod==2) str=str "nd"; else if (mod==3) str=str "rd"; else str=str "th"; return str;} /system command/&&/information description/ { gsub(/"/,"") ; print ordinal(++i) ") Command = " $3}' file

1st) Command = set1
2nd) Command = 21-22
3rd) Command = T1-T2-T3
4th) Command = commonset

Expanded form:

awk '
function ordinal(i,   mod, str) {
   mod = i%10
   str = i
   if (i~/1[1-3]$/)  # for numbers ending in 11, 12, 13
      str = str "th"
   else if (mod==1)
      str = str "st"
   else if (mod==2)
      str = str "nd"
   else if (mod==3)
      str = str "rd"
   else
      str = str "th"
   return str
}
/system command/&&/information description/ {
   gsub(/"/,"")
   print ordinal(++i) ") Command = " $3
}' file

An alternative way to implement the above function would be:

function ordinal(num,   idx, sfxs) {
   split("st nd rd th",sfxs," ")
   idx = ( (num ~ /[123]$/) && (num !~ /1[123]$/) ? num % 10 : 4 )
   return num sfxs[idx]
}